dev-python/black-21.9_beta0: Version bump

Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

2 files changed, 60 insertions, 0 deletions

diff --git a/dev-python/black/Manifest b/dev-python/black/Manifest
index 111fcee34bc9..e4d9a1bfbc0f 100644
--- a/dev-python/black/Manifest
+++ b/dev-python/black/Manifest
@@ -1,3 +1,4 @@
 DIST black-20.8b1.tar.gz 1092546 BLAKE2B 5a0a755222617d8d551b627c91670ecc32a9330cc1197900a9d21b071d0d99ddd32e09786becfc577407ab402f6da3d8683a59a9deaea1f6b4f07b9e1e4ecbed SHA512 53d6f6a6f47027e5bdfd3909471c993480034c8aa8ae395792565b8d79fb4e3a44299ea529652c0ccabf4309d645db9179bf54efc06fee20517f479e91cec838
 DIST black-21.7b0.tar.gz 1148431 BLAKE2B 34dcd2fd45b914433d6290c10bb07b44277cb490ef884c44ec00cb5495fadd2e649099dd356c4063d0fff5a6477609b11db73e1dc94d88106c56a3ca9b087c90 SHA512 7e6ee4e185080802c9dfc6eeb73b52b2489283c4bcbc086366f50ffb8ea3e0f4bdfedac9a5906be6ec119e65050741c71591c394f0c361a1d75b3ff4061945c1
 DIST black-21.8b0.tar.gz 1167978 BLAKE2B e7df398d09b71389069991bf0872a97d8a8c0b13ddeec12ee8f08ae9d9716a3d47447727d2759d475f10d323df151b8bb2353f3fd60c99eccb1e912554ebbe7b SHA512 ed38dbf0c881fee7da74f0d6bfe4ea0f85b5bed30d37abde2fd728e33f94ceaaa27b7107cfe763c19bdaea57fcbf54bcae82ce8bdcabc29035cdc85a8e10ab00
+DIST black-21.9b0.tar.gz 1167869 BLAKE2B 31933de69cc34e23e14b0fdba33da844697816cd3917227c1a16c4d1595435d3715405f7f1df820953e83c30c3947448389a703ee662548226dfc2d278b87844 SHA512 0c8025d64ef9e5da8ad73b1f265b912bcb3d8cb00d8a426a39dd4c70505a77150e02a7f26e3d6842456eea367da9fad29d08f586b175d57d66a09cf389442ed0
diff --git a/dev-python/black/black-21.9_beta0.ebuild b/dev-python/black/black-21.9_beta0.ebuild
new file mode 100644
index 000000000000..58c092b5e346
--- /dev/null
+++ b/dev-python/black/black-21.9_beta0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 optfeature
+
+MY_PV="${PV//_beta/b}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="https://black.readthedocs.io/en/stable/ https://github.com/psf/black"
+SRC_URI="https://github.com/psf/${PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	<dev-python/pathspec-1[${PYTHON_USEDEP}]
+	<dev-python/tomli-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${MY_PV}
+
+src_prepare() {
+	# remove unnecessary bind that worked around broken 6.1.0/6.2.0 releases
+	sed -i -e '/setuptools_scm/s:~=:>=:' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cp "${S}"/src/black_primer/primer.json \
+		"${BUILD_DIR}"/lib/black_primer/primer.json || die
+	distutils_install_for_testing
+	epytest -m "not python2"
+}
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" dev-python/aiohttp dev-python/aiohttp-cors
+}