proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 67 insertions, 0 deletions

diff --git a/dev-python/bpython/bpython-0.13.1.ebuild b/dev-python/bpython/bpython-0.13.1.ebuild
new file mode 100644
index 000000000000..bbf09b6c3b15
--- /dev/null
+++ b/dev-python/bpython/bpython-0.13.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
+HOMEPAGE="http://www.bpython-interpreter.org/ https://bitbucket.org/bobf/bpython/ http://pypi.python.org/pypi/bpython"
+SRC_URI="http://www.bpython-interpreter.org/releases/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc gtk test"
+
+RDEPEND="
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	gtk? ( dev-python/pygobject:2[$(python_gen_usedep python2_7)]
+		dev-python/pygtk[$(python_gen_usedep python2_7)] )
+	dev-python/urwid[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+DOCS=( AUTHORS  CHANGELOG  TODO sample-config sample.theme light.theme )
+
+PATCHES=( "${FILESDIR}"/${PN}-desktop.patch
+		"${FILESDIR}"/${PN}-0.13-test_repl.patch )
+
+# Req'd for clean build by each impl
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build -b html -c doc/sphinx/source/ \
+			doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use gtk; then
+		rm -f "${D}"usr/bin/bpython-gtk*
+		# delete_unneeded_modules() {
+		rm -f "${D}$(python_get_sitedir)/bpython/gtk_.py"
+	fi
+}
+
+python_test() {
+	pushd build/lib > /dev/null
+	# https://bitbucket.org/bobf/bpython/issue/289/test-failures-in-latest-release-py27-py33
+	sed -e s':test_enter:_&:' -i bpython/test/test_repl.py || die
+
+	"${PYTHON}" -m unittest discover || die
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
+	distutils-r1_python_install_all
+}