dev-python/cairocffi: bump to 0.9.0

Signed-off-by: Virgil Dupras <vdupras@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/cairocffi/cairocffi-0.9.0.ebuild b/dev-python/cairocffi/cairocffi-0.9.0.ebuild
new file mode 100644
index 000000000000..7291340fb126
--- /dev/null
+++ b/dev-python/cairocffi/cairocffi-0.9.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1 virtualx
+
+MY_PN="${PN}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="CFFI-based drop-in replacement for Pycairo"
+HOMEPAGE="https://github.com/Kozea/cairocffi"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	$(python_gen_cond_dep '>=dev-python/cffi-1.1.0:=[${PYTHON_USEDEP}]' 'python*')
+	>=dev-python/xcffib-0.3.2[${PYTHON_USEDEP}]
+	x11-libs/cairo:0=[xcb]
+	x11-libs/gdk-pixbuf[jpeg]
+	$(python_gen_cond_dep '>=virtual/pypy-2.6.0' pypy )"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	$(python_gen_cond_dep '>=virtual/pypy-2.6.0' pypy )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	virtx py.test -v --pyargs cairocffi -o addopts= || die "testsuite failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}