dev-python/docker-py: 5.0.0

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-3.0.18, Repoman-3.0.3

2 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/docker-py/Manifest b/dev-python/docker-py/Manifest
index fdc92972dcec..8ddc8ec57523 100644
--- a/dev-python/docker-py/Manifest
+++ b/dev-python/docker-py/Manifest
@@ -1 +1,2 @@
 DIST docker-py-4.4.4.tar.gz 247640 BLAKE2B 68b2e0d41e68fdf4826d61b7ab167321467b1b30f122f0b29955a62ac5f036fc0b60b02a8c9a6776ffd9a7cafb5744de44ec3b9284d0f266a1dd5c72fbec2879 SHA512 4106ffe353ce8c3227c30c38347f107e0f7da660f1c3ae68bf2c576fc6b270f6fae6774747c46491eae0fc85a48dfe246b7a22d8e45c74eff89ed43be285f0df
+DIST docker-py-5.0.0.tar.gz 247639 BLAKE2B 7e7f1d0edf228c967ee9252c6dc37e803a2e91601d3dce06db335c4bc4c8af43097864307ad72d4665d13f9ab0ba63b3dfd5ac7baa4dbc903ca57fe67985c1d2 SHA512 fae4afcda91ddf946048f76e62928a4891e1b0ce522b820aefb774dde58eb8e2aac0a381971acca04ca87794989ba675464e7913fab4abf2ed414719d66c91d1
diff --git a/dev-python/docker-py/docker-py-5.0.0.ebuild b/dev-python/docker-py/docker-py-5.0.0.ebuild
new file mode 100644
index 000000000000..6cfc62e02e87
--- /dev/null
+++ b/dev-python/docker-py/docker-py-5.0.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Docker"
+HOMEPAGE="https://github.com/docker/docker-py"
+SRC_URI="https://github.com/docker/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.24.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-0.32.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/paramiko-2.4.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/recommonmark' \
+	'>=dev-python/sphinx-1.4.6'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# localhost has a better chance of being in /etc/hosts
+	sed -e 's:socket[.]gethostname():"localhost":' \
+		-i tests/unit/api_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	pytest -vv tests/unit/ || die "tests failed under ${EPYTHON}"
+}