dev-python/gammapy: version bump

Package-Manager: portage-2.3.2

1 files changed, 74 insertions, 0 deletions

diff --git a/dev-python/gammapy/gammapy-0.5.ebuild b/dev-python/gammapy/gammapy-0.5.ebuild
new file mode 100644
index 000000000000..55255ea7749a
--- /dev/null
+++ b/dev-python/gammapy/gammapy-0.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+inherit distutils-r1 eutils virtualx xdg-utils
+
+DESCRIPTION="Python package for gamma-ray astronomy"
+HOMEPAGE="https://gammapy.readthedocs.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+DOCS=( README.rst )
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/regions[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "${PN} full functionality" \
+			   dev-python/aplpy \
+			   dev-python/astroplan \
+			   dev-python/h5py \
+			   dev-python/iminuit \
+			   dev-python/matplotlib \
+			   dev-python/naima \
+			   dev-python/pandas \
+			   dev-python/photutils \
+			   dev-python/reproject \
+			   dev-python/wcsaxes \
+			   sci-libs/scipy \
+			   sci-libs/scikits_image \
+			   sci-libs/scikits_learn
+	# not yet in portage: sherpa, gwcs, uncertainties
+}