dev-python/hypothesis: version bump to 4.15.0

Signed-off-by: Tim Harder <radhermit@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/hypothesis/hypothesis-4.15.0.ebuild b/dev-python/hypothesis/hypothesis-4.15.0.ebuild
new file mode 100644
index 000000000000..b3f2ee27292c
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-4.15.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy{,3} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd"
+IUSE="test"
+
+CDEPEND="
+	>=dev-python/attrs-16.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' 'python2*' pypy)
+"
+RDEPEND="${CDEPEND}"
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+python_test() {
+	py.test -v tests/cover/test_testdecorators.py || die "Tests fail with ${EPYTHON}"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}