dev-python/ipykernel: specify python major version in kernelspec

  Revision bump and remove old revisions.

Credit: Eric Hermes
Bug: 628222

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild b/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild
new file mode 100644
index 000000000000..01461f099319
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="https://github.com/ipython/ipykernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/ipython-4.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '<dev-python/ipython-6[${PYTHON_USEDEP}]' 'python2*')
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.1.0[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
+	)
+"
+
+python_install() {
+	distutils-r1_python_install
+
+	# bug 628222, specify python 2 or 3.
+	sed -e "s:python:${EPYTHON}:" \
+		-i "${ED}"usr/share/jupyter/kernels/${EPYTHON%.*}/kernel.json || die
+}
+
+python_test() {
+	nosetests --verbose ipykernel || die
+}