dev-python/libcloud: add new version 2.3.0

Cloned from 1.5.0 ebuild.
Changes:
 * added "|| die" as needed
 * stopped using EXAMPLES var which is banned since EAPI=6
 * upgraded EAPI to 7
 * dropped old cryptic comment "py3 dropped due to failing tests..."

Closes: https://github.com/gentoo/gentoo/pull/8399
Package-Manager: Portage-2.3.36, Repoman-2.3.9

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/libcloud/libcloud-2.3.0.ebuild b/dev-python/libcloud/libcloud-2.3.0.ebuild
new file mode 100644
index 000000000000..93bc7ecbd443
--- /dev/null
+++ b/dev-python/libcloud/libcloud-2.3.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Unified Interface to the Cloud - python support libs"
+HOMEPAGE="https://libcloud.apache.org/"
+SRC_URI="mirror://apache/${PN}/apache-${P}.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND=""
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/lockfile[${PYTHON_USEDEP}]
+		 $(python_gen_cond_dep 'dev-python/backports-ssl-match-hostname[${PYTHON_USEDEP}]' python{2_7,3_4} pypy)
+	)"
+
+# Known test failures
+RESTRICT="test"
+
+S="${WORKDIR}/apache-${P}"
+
+python_prepare_all() {
+	if use examples; then
+		mkdir examples || die
+		mv example_*.py examples || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	cp libcloud/test/secrets.py-dist libcloud/test/secrets.py || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}