dev-python/more-itertools: bump to 3.0.0, add py3.6, pypy, pypy3

- Version 3.0.0 is now compatible with PyPy and PyPy3
- Add a new dependency
- Add GitHub upstream and bugs-to to metadata
- Bump to EAPI 6

Closes: https://github.com/gentoo/gentoo/pull/4590
Package-Manager: Portage-2.3.5, Repoman-2.3.2

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-python/more-itertools/more-itertools-3.0.0.ebuild b/dev-python/more-itertools/more-itertools-3.0.0.ebuild
new file mode 100644
index 000000000000..3c7a53ab430e
--- /dev/null
+++ b/dev-python/more-itertools/more-itertools-3.0.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy{,3} )
+
+inherit distutils-r1
+
+DESCRIPTION="More routines for operating on iterables, beyond itertools"
+HOMEPAGE="https://pypi.python.org/pypi/more-itertools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="<dev-python/six-2.0[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests -v -w "${BUILD_DIR}" more_itertools --with-doctest \
+		|| die "tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}