dev-python/msgpack: version bump to 0.5.6.

Add native-extensions USE flag to conditionally disable C extensions.

Closes: https://github.com/gentoo/gentoo/pull/7176

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/msgpack/msgpack-0.5.6.ebuild b/dev-python/msgpack/msgpack-0.5.6.ebuild
new file mode 100644
index 000000000000..c983343b0e3a
--- /dev/null
+++ b/dev-python/msgpack/msgpack-0.5.6.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="MessagePack (de)serializer for Python"
+HOMEPAGE="http://msgpack.org https://github.com/msgpack/msgpack-python/ https://pypi.python.org/pypi/msgpack/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+IUSE="+native-extensions test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	native-extensions? (
+		>=dev-python/cython-0.16[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Remove pre-generated cython files
+	rm msgpack/{_packer,_unpacker}.cpp || die
+
+	if ! use native-extensions ; then
+		sed -i -e "/have_cython/s:True:False:" ./setup.py || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -v test || die "Tests fail with ${EPYTHON}"
+}