dev-python/naima: add addpredict workaround during install

Bug hard to reproduce.
Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=604012

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/naima/naima-0.8-r1.ebuild b/dev-python/naima/naima-0.8-r1.ebuild
new file mode 100644
index 000000000000..749dafc253c1
--- /dev/null
+++ b/dev-python/naima/naima-0.8-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 eutils xdg-utils
+
+DESCRIPTION="Python package for gamma-ray astronomy"
+HOMEPAGE="http://naima.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+DOCS=( README.rst )
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	dev-python/corner[${PYTHON_USEDEP}]
+	dev-python/emcee[${PYTHON_USEDEP}]
+	dev-python/h5py[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]"
+
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (	dev-python/pytest[${PYTHON_USEDEP}] )"
+
+DOCS=( README.rst CHANGES.rst )
+
+python_prepare_all() {
+	sed -e '/auto_use/s/True/False/' -i setup.cfg || die
+	xdg_environment_reset
+	# issues during install time (bug #604012)
+	addpredict /proc/mtrr
+	addpredict /sys/devices/system/cpu/
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}