proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 82 insertions, 0 deletions

diff --git a/dev-python/paste/paste-1.7.5.1-r2.ebuild b/dev-python/paste/paste-1.7.5.1-r2.ebuild
new file mode 100644
index 000000000000..1267db6af929
--- /dev/null
+++ b/dev-python/paste/paste-1.7.5.1-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+# notes wrt py-3 compatibility:
+# Debian ships paste for py3 using 2to3. Many tests fail when using such converted code and
+# the fact that the errors are sometimes nested inside paste indicate that the
+# result is indeed broken. Upstream is not responsive nor interested in porting.
+
+inherit distutils-r1
+
+MY_PN="Paste"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Tools for using a Web Server Gateway Interface stack"
+HOMEPAGE="http://pythonpaste.org http://pypi.python.org/pypi/Paste"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-interix ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris"
+IUSE="doc flup openid"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/tempita-0.5.2_pre20130828[${PYTHON_USEDEP}]
+	flup? ( dev-python/flup[${PYTHON_USEDEP}] )
+	openid? ( dev-python/python-openid[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# Disable failing tests.
+	rm -f tests/test_cgiapp.py
+	sed \
+		-e "s/test_find_file/_&/" \
+		-e "s/test_deep/_&/" \
+		-e "s/test_static_parser/_&/" \
+		-i tests/test_urlparser.py || die "sed failed"
+
+	# Remove a test that runs against the paste website.
+	rm -f tests/test_proxy.py
+
+	local PATCHES=(
+		"${FILESDIR}/${P}-fix-tests-for-pypy.patch"
+		"${FILESDIR}/${P}-python27-lambda.patch"
+		"${FILESDIR}/${P}-unbundle-stdlib.patch"
+		"${FILESDIR}/${P}-unbundle-tempita.patch"
+		"${FILESDIR}/${P}-userdict.patch"
+		"${FILESDIR}/${P}-rfc822.patch"
+		"${FILESDIR}/${P}-email-mime.patch"
+		"${FILESDIR}/${P}-types.patch"
+		"${FILESDIR}/${P}-hmac.patch"
+	)
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile egg_info --egg-base "${BUILD_DIR}/lib"
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	nosetests -P || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install egg_info --egg-base "${BUILD_DIR}/lib"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}