dev-python/paver: version bump.

Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/paver/paver-1.3.4.ebuild b/dev-python/paver/paver-1.3.4.ebuild
new file mode 100644
index 000000000000..addd2dd324bf
--- /dev/null
+++ b/dev-python/paver/paver-1.3.4.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} pypy )
+
+inherit distutils-r1
+
+MY_PN=${PN/p/P}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python-based software project scripting tool along the lines of Make"
+HOMEPAGE="http://www.blueskyonmars.com/projects/paver/ https://github.com/paver/paver"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
+IUSE="test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# https://github.com/paver/paver/issues/143#issuecomment-103943327
+	find paver/tests -name '*.pyc' -delete || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests || die "Testing failed with ${EPYTHON}"
+}