dev-python/pbr: Bump to 5.6.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 73 insertions, 1 deletions

diff --git a/dev-python/pbr/Manifest b/dev-python/pbr/Manifest
index 6992113a24bc..cb9ef7dc5cb5 100644
--- a/dev-python/pbr/Manifest
+++ b/dev-python/pbr/Manifest
@@ -1 +1,2 @@
 DIST pbr-5.5.1.tar.gz 117488 BLAKE2B 52deecc6107d739daec0b2d3c397285c87c63bb3d2a2abc8266feec78d43eff84f4093b9739e2bbdf47b604a1621e4ed809a689b2167e6ea673418bd27f29018 SHA512 c72c2bb8bedd7f0606880f003dffa0ed585521b698e3e986ed2913cd74303e281fbb2374cc1a00b76777c677eb2677507eed9ccaafefceee0a689cb6fa61bab6
+DIST pbr-5.6.0.tar.gz 125220 BLAKE2B fc26737857195b0dbe16ecbcbc6e389b53a61105b3bc66e714bb4fcb4907e4329ee7c76b5748fa7d892bf231522e6ff9d414328ae0d97e6262b608c44c737764 SHA512 1dca9020a84e3b9be71fa07e2feb37bbdb2bb69d0b4f69fdcee0fc3c7fe4d84ac2e2079d6bd7560192833f069ca6f5dc27d03a3ef87c168eed18eee8579647fc
diff --git a/dev-python/pbr/metadata.xml b/dev-python/pbr/metadata.xml
index aa7c0d694563..f67a700ab002 100644
--- a/dev-python/pbr/metadata.xml
+++ b/dev-python/pbr/metadata.xml
@@ -20,6 +20,6 @@
   <stabilize-allarches/>
   <upstream>
     <remote-id type="pypi">pbr</remote-id>
-    <remote-id type="github">openstack-dev/pbr</remote-id>
+    <remote-id type="github">openstack/pbr</remote-id>
   </upstream>
 </pkgmetadata>
diff --git a/dev-python/pbr/pbr-5.6.0.ebuild b/dev-python/pbr/pbr-5.6.0.ebuild
new file mode 100644
index 000000000000..60fecc79e508
--- /dev/null
+++ b/dev-python/pbr/pbr-5.6.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="https://github.com/openstack/pbr/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and https://bugs.gentoo.org/show_bug.cgi?id=561038
+# docutils is needed for sphinx exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848
+# stestr is run as external tool
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			>=dev-python/stestr-2.1.0[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' 'python*')
+	)"
+PDEPEND=""
+
+# This normally actually belongs here.
+python_prepare_all() {
+	# TODO: investigate
+	sed -e s':test_console_script_develop:_&:' \
+		-e s':test_console_script_install:_&:' \
+		-i pbr/tests/test_core.py || die
+	# broken on pypy3
+	# https://bugs.launchpad.net/pbr/+bug/1881479
+	sed -e 's:test_generates_c_extensions:_&:' \
+		-i pbr/tests/test_packaging.py || die
+	rm pbr/tests/test_wsgi.py || die "couldn't remove wsgi network tests"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if [[ ${EPYTHON} == pypy3 ]]; then
+		einfo "Testing on ${EPYTHON} is not supported at the moment"
+		return
+	fi
+
+	distutils_install_for_testing
+	local -x PATH=${TEST_DIR}/scripts:${PATH}
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	stestr init || die "stestr init failed under ${EPYTHON}"
+	stestr run || die "stestr run failed under ${EPYTHON}"
+}