dev-python/peewee bump, rm old

Package-Manager: portage-2.2.20

1 files changed, 38 insertions, 0 deletions

diff --git a/dev-python/peewee/peewee-2.6.3.ebuild b/dev-python/peewee/peewee-2.6.3.ebuild
new file mode 100644
index 000000000000..378bd7a033ce
--- /dev/null
+++ b/dev-python/peewee/peewee-2.6.3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Small python ORM"
+HOMEPAGE="https://github.com/coleifer/peewee/"
+SRC_URI="https://github.com/coleifer/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+# Req'd to ensure a unique tmp.db for each python impl running the testsuite.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# Testsuite run using runtests.py does not require deps listed in previous ebuild
+	"${PYTHON}" ./runtests.py || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}