dev-python/py-amqp: 2.2.1 bup

Package-Manager: Portage-2.3.6, Repoman-2.3.3

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/py-amqp/py-amqp-2.2.1.ebuild b/dev-python/py-amqp/py-amqp-2.2.1.ebuild
new file mode 100644
index 000000000000..399c006bd586
--- /dev/null
+++ b/dev-python/py-amqp/py-amqp-2.2.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+MY_PN="amqp"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
+HOMEPAGE="https://github.com/celery/py-amqp https://pypi.python.org/pypi/amqp/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc extras test"
+
+RDEPEND=""
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/vine-1.1.3[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_celery[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/case-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.0[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	if use extras; then
+		insinto /usr/share/${PF}/extras
+		doins -r extra
+	fi
+	distutils-r1_python_install_all
+}