dev-python/pyftpdlib: version bump to 1.5.2, add Python 3.6.

Package-Manager: Portage-2.3.6, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/4893

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-python/pyftpdlib/pyftpdlib-1.5.2.ebuild b/dev-python/pyftpdlib/pyftpdlib-1.5.2.ebuild
new file mode 100644
index 000000000000..f7df1f99fbcf
--- /dev/null
+++ b/dev-python/pyftpdlib/pyftpdlib-1.5.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python FTP server library"
+HOMEPAGE="https://github.com/giampaolo/pyftpdlib https://pypi.python.org/pypi/pyftpdlib"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
+IUSE="examples ssl test"
+
+RDEPEND="ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}] )"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND} )
+"
+
+python_test() {
+	# Tests may fail occasionally
+	# https://github.com/giampaolo/pyftpdlib/issues/420
+	"${EPYTHON}" ${PN}/test/runner.py || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] && \
+		[[ ${PYTHON_TARGETS} == *python2_7* ]] && \
+		! has_version dev-python/pysendfile ; then
+		elog "dev-python/pysendfile is not installed"
+		elog "It can considerably speed up file transfers for Python 2"
+	fi
+}