dev-python/pyro: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 0 insertions, 62 deletions

diff --git a/dev-python/pyro/pyro-4.77.ebuild b/dev-python/pyro/pyro-4.77.ebuild
deleted file mode 100644
index 3a5e54619e51..000000000000
--- a/dev-python/pyro/pyro-4.77.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=( python3_{6,7} )
-
-inherit distutils-r1
-
-MY_PN="Pyro4"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="Distributed object middleware for Python (RPC)"
-HOMEPAGE="https://pypi.org/project/Pyro4/
-	https://github.com/irmen/Pyro4"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="4"
-KEYWORDS="amd64 ~arm64 ppc x86"
-IUSE="doc examples test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	!dev-python/pyro:0
-	>=dev-python/serpent-1.27[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	test? (
-		>=dev-python/cloudpickle-1.2.1[${PYTHON_USEDEP}]
-		dev-python/dill[${PYTHON_USEDEP}]
-		>=dev-python/msgpack-0.4.6[${PYTHON_USEDEP}]
-	)"
-
-S="${WORKDIR}/${MY_P}"
-
-python_prepare_all() {
-	# Disable tests requiring network connection.
-	rm tests/PyroTests/test_naming.py || die
-	sed \
-		-e "s/testStartNSfunc/_&/" \
-		-i tests/PyroTests/test_naming2.py || die
-
-	sed \
-		-e "s/testBroadcast/_&/" \
-		-e "s/testGetIP/_&/" \
-		-i tests/PyroTests/test_socket.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_test() {
-	esetup.py test
-}
-
-python_install_all() {
-	use doc && HTML_DOCS=( docs/. )
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-	distutils-r1_python_install_all
-}