dev-python/pyro: version bump to 4.56

Package-Manager: Portage-2.3.4, Repoman-2.3.2

2 files changed, 77 insertions, 0 deletions

diff --git a/dev-python/pyro/Manifest b/dev-python/pyro/Manifest
index 0839d1d51653..1bc03f6fa9fe 100644
--- a/dev-python/pyro/Manifest
+++ b/dev-python/pyro/Manifest
@@ -4,3 +4,4 @@ DIST Pyro4-4.39.tar.gz 496566 SHA256 39c6ca7f86b0f0bebfeada687a5a8b99f66470a52b0
 DIST Pyro4-4.40.tar.gz 501340 SHA256 00423d3710f60b2da146075a59e17bfa837f556ed2c8acafe05bc209dcaac3e9 SHA512 43ee1b0dd3e700d9fed16c5fceda30074dc6cd3cbd466efe911711eb81f1c4bce1967bed06225922e45812e04e36c49cd42d24c0edca1845159d1035326896e7 WHIRLPOOL fdc5f2f405a217db0840218201b1d943ef5828513cc606135dbe5dd7fb723dedec78ad25e8ea6cc2ca0a3e4b374eb8a73fe7db0dae6dcac117c0af9d0e757def
 DIST Pyro4-4.41.tar.gz 502294 SHA256 3af4749140e9d4032632277ac19e7fd4761856d2df0f0643c574d1e7174a9703 SHA512 01c3f16448b39cd7a83c845eec86013315ee183a3e50c6caee1d327308e67ff63732833b413b189ebcb77cdb3fc65bbd7417ecbfc8575775ff79550678bce020 WHIRLPOOL 4ff63737b01eca22bc1dcd7e61a81ad3285c90ac1e03764edffe85b003eade780a936bbd74773f8d58d2a34dbe562bdfe332c5dd8ddd052f5a3928caa736d882
 DIST Pyro4-4.47.tar.gz 437077 SHA256 9354b722f9f5965ade5839241c8d7ff06ec2fac678a2c9e197a63966da241c89 SHA512 5879cad65ba32fc735d002037bbdb9ee1ef7e61e169306f5ec5e6bb771478c17ddde621d8b73ff4ddff8ffb1307a25f7851bc5c96f8ff8689aa6d74d1157cd8b WHIRLPOOL 4e81666ca26d6bef337b952db5f906e37deb5e544bc936bc6fc798378102dfee3e24c03b8e69dfd6e7e4ba42d96a82310709ef98430d4a47c4a094048cca49fd
+DIST Pyro4-4.56.tar.gz 455253 SHA256 a80c27e1debbd8d8725ee4a8f0d30cf831dde5e80b04bfa9c912932c4c13d6aa SHA512 88805f5d7108432f98d38267a7a881e35fc1e34ae32cc7a1640f4b6e0d69718a86bf195fb4e4eecbd53075667521585b7006cd5c5736e5ff1ed39b5212b91bef WHIRLPOOL 0e82a13c2bf5e23c5fcbf844417888fd2e02270a12d465c6388397c913bbb06ebdc770d3744593d66b9b30ffc30aeda03a50dd934db38840ba1baeeb80961ff7
diff --git a/dev-python/pyro/pyro-4.56.ebuild b/dev-python/pyro/pyro-4.56.ebuild
new file mode 100644
index 000000000000..f20108be3dec
--- /dev/null
+++ b/dev-python/pyro/pyro-4.56.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5,6} pypy )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="http://www.xs4all.nl/~irmen/pyro/ https://pypi.python.org/pypi/Pyro4 https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND="
+	!dev-python/pyro:0
+	$(python_gen_cond_dep \
+		'dev-python/selectors34[${PYTHON_USEDEP}]' python{2_7,3_3})
+	>=dev-python/serpent-1.11[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/dill[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.4.6[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	sed \
+		-e '/sys.path.insert/a sys.path.insert(1,"PyroTests")' \
+		-i tests/run_testsuite.py || die
+
+	# Disable tests requiring network connection.
+	rm tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testOwnloopBasics/_&/" \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testServerConnections/_&/" \
+	    -e "s/testServerParallelism/_&/" \
+		-i tests/PyroTests/test_server.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-e "s/testGetIpVersion[46]/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pushd "${S}"/tests >/dev/null || die
+	PYTHONPATH=../src ${PYTHON} run_testsuite.py || die
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}