dev-python/slimit: revbump to silence warning on module import

Closes: https://bugs.gentoo.org/660510
Closes: https://github.com/gentoo/gentoo/pull/9068
Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/slimit/slimit-0.8.1-r1.ebuild b/dev-python/slimit/slimit-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..b4561d3f8de2
--- /dev/null
+++ b/dev-python/slimit/slimit-0.8.1-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 pypy{,3} python3_{4,5,6} )
+inherit distutils-r1
+
+DESCRIPTION="A JavaScript minifier written in Python"
+HOMEPAGE="https://slimit.readthedocs.io/en/latest/"
+SRC_URI="https://github.com/rspivak/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/ply:=[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}/${P}-fix-python3.patch" )
+
+python_compile() {
+	distutils-r1_python_compile
+
+	rm "${BUILD_DIR}"/lib/slimit/*tab.py || die
+
+	# Regenerate yacctab.py and lextab.py files to avoid warnings whenever
+	# the module is imported. See https://github.com/rspivak/slimit/issues/97
+	# for details
+	"${EPYTHON}" -B -c 'import slimit;slimit.minify("")' || die
+}
+
+python_test() {
+	esetup.py pytest --addopts "${BUILD_DIR}" || die "Testing failed with ${EPYTHON}"
+}