dev-python/urwidtrees: Bump version

Sources URI has changed from PyPI to GitHub.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/urwidtrees/urwidtrees-1.0.2.ebuild b/dev-python/urwidtrees/urwidtrees-1.0.2.ebuild
new file mode 100644
index 000000000000..26a98d8ca215
--- /dev/null
+++ b/dev-python/urwidtrees/urwidtrees-1.0.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="Tree widgets for urwid"
+HOMEPAGE="https://github.com/pazz/urwidtrees"
+#SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+SRC_URI="https://github.com/pazz/urwidtrees/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+RDEPEND=">=dev-python/urwid-1.1.0[${PYTHON_USEDEP}]"
+
+src_prepare() {
+	find "${S}" -name '*.py' -print0 | xargs -0 -- sed \
+		-e '1i# -*- coding: utf-8 -*-' -i || die
+
+	distutils-r1_src_prepare
+
+	local md
+	for md in *.md; do
+		mv "${md}" "${md%.md}"
+	done
+}
+
+src_compile() {
+	distutils-r1_src_compile
+
+	if use doc; then
+		pushd docs || die
+		emake html
+		popd || die
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	if use doc; then
+		dohtml -r docs/build/html/*
+	fi
+}