dev-python/webtest: Version bump to 2.0.33

Copyright: Sony Interactive Entertainment Inc.
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

1 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/webtest/webtest-2.0.33.ebuild b/dev-python/webtest/webtest-2.0.33.ebuild
new file mode 100644
index 000000000000..f7c319ecf357
--- /dev/null
+++ b/dev-python/webtest/webtest-2.0.33.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit distutils-r1
+
+MY_PN="WebTest"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Helper to test WSGI applications"
+HOMEPAGE="https://pypi.org/project/WebTest/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="doc test"
+
+# nose<1.3.0 appears a leftover never updated in requires.txt. tests pass fine with latest
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/webob-1.2[${PYTHON_USEDEP}]
+	>=dev-python/waitress-0.8.5[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( $(python_gen_any_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pyquery[${PYTHON_USEDEP}]
+		dev-python/pastedeploy[${PYTHON_USEDEP}]
+		dev-python/wsgiproxy2[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 )
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+# Makes testing easier; otherwise we get errors from pkg_resources.
+#DISTUTILS_IN_SOURCE_BUILD=1
+PATCHES=(
+	"${FILESDIR}/webtest-2.0.33-no-pylons-theme.patch"
+)
+
+python_check_deps() {
+	use doc || return 0
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# Prevent un-needed d'loading during doc build
+	sed -i -e 's:^intersphinx_mapping:disabled_&: ; s:^templates_path:#&:' \
+		docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build docs html || die
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	# Tests raise ImportErrors with our default PYTHONPATH.
+	local -x PYTHONPATH=
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( html/. )
+	distutils-r1_python_install_all
+}