dev-python/pygame: Bump to 2.0.0dev14

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/dev-python/pygame/Manifest b/dev-python/pygame/Manifest
index 30e13a75e670..ffdad2b609c6 100644
--- a/dev-python/pygame/Manifest
+++ b/dev-python/pygame/Manifest
@@ -1,3 +1,4 @@
 DIST pygame-1.9.6.tar.gz 3223131 BLAKE2B a4d04c933fcad244d32bd512ef8717e60ec923f361e9e0296b5c7d57c5949d3434a040d028249c5b8f3c865ac3dcdbb32e6f0b223186678595a8625213ba2a17 SHA512 d923c554203a7c35e37921658cb4c5bf50215ab0ff4d2b869a1ee6b2e2ca31d66ec4bbde4287f5a777838ffe932cd15b993cb0224b86e43d684de61c35acbcd0
 DIST pygame-2.0.0.dev10.tar.gz 5567274 BLAKE2B 7d78f260318cfabeb33f1073ae210f890d2f772e3ef302f243cca67724c6012355644ba60d4cae6de72db6dd61d320177deff6ee83dd355ec4cc33e841b565f7 SHA512 4cee7599fd8a6d31ddd66bfaad3bbb67cb167c1ae339f37e83322d810fea8746e81a191c224a0eeb6cc43a64bf1730ff0886c82f1a4f642e2e656ca9a837bf9e
 DIST pygame-2.0.0.dev12.tar.gz 5598471 BLAKE2B 339e96ed7f01070c3aa4b31b587a793b43b99ac476d72a431dff09d98b95ef48c6b0d4faa20301e6db43cb2b35b13245253d86859c16d2befbd3795f8ed48b7f SHA512 f732056b3c8377326caf1d6ded6c59e8665de2ab2f6233d6d95dcc26137d67d180f8c5dc92fc22578ec5ce0ecf5a1de5080c62355d15035ab248d518cd75180f
+DIST pygame-2.0.0.dev14.tar.gz 5556790 BLAKE2B 9857a8bc14081c375d717c50b7406f74a52ae725c31905acc2528f8d361d9b1e54e2f20383f553c6f3a290d2fbdbc2342c88c7a7a0abee3f6038ed737747a7a0 SHA512 37490dbb981cc889f00036162baa450f6cc6b936cfb23b5648ed43a8c524e8782c71efcfaef2c2ddf9690c946b0f5d15c670dddcb730f18dc37b28d06c13ae3b
diff --git a/dev-python/pygame/pygame-2.0.0_pre14.ebuild b/dev-python/pygame/pygame-2.0.0_pre14.ebuild
new file mode 100644
index 000000000000..a43bd4b42236
--- /dev/null
+++ b/dev-python/pygame/pygame-2.0.0_pre14.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1
+
+MY_PV=${PV/_pre/.dev}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python bindings for SDL multimedia library"
+HOMEPAGE="https://www.pygame.org/"
+SRC_URI="
+	https://github.com/pygame/pygame/releases/download/${MY_PV}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc examples midi opengl test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	media-libs/freetype
+	>=media-libs/sdl2-image-1.2.2
+	>=media-libs/sdl2-mixer-1.2.4
+	>=media-libs/sdl2-ttf-2.0.6
+	>=media-libs/smpeg2-0.4.4-r1
+	midi? ( media-libs/portmidi )
+	X? ( >=media-libs/libsdl2-1.2.5[opengl?,threads,video,X] )
+	!X? ( >=media-libs/libsdl2-1.2.5[threads] )"
+DEPEND="${RDEPEND}
+	test? (
+		media-libs/sdl2-image[gif,jpeg,png]
+		media-libs/sdl2-mixer[mp3,vorbis,wav]
+	)"
+# fontconfig used for fc-list
+RDEPEND+="
+	media-libs/fontconfig"
+# util-linux provides script
+BDEPEND="
+	test? (
+		media-libs/fontconfig
+		sys-apps/util-linux
+	)"
+
+src_prepare() {
+	if ! use midi; then
+		rm test/midi_test.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	PORTMIDI_INC_PORTTIME=1 LOCALBASE="${EPREFIX}/usr" \
+		"${EPYTHON}" "${S}"/buildconfig/config.py -auto || die
+
+	# Disable automagic dependency on PortMidi.
+	if ! use midi; then
+		sed -e "s:^pypm :#&:" -i Setup || die "sed failed"
+	fi
+}
+
+python_test() {
+	local -x PYTHONPATH=${BUILD_DIR}/install/lib
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=disk
+	esetup.py install \
+		--root="${BUILD_DIR}"/install \
+		--install-lib=lib
+	script -eqc "${EPYTHON} -m pygame.tests" || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Bug #497720
+	rm -fr "${D}"$(python_get_sitedir)/pygame/{docs,examples,tests}/ || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		docinto html
+		dodoc -r docs/*
+	fi
+
+	use examples && dodoc -r examples
+}