dev-ruby/gruff: add 0.7.0

Package-Manager: portage-2.2.28

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-ruby/gruff/gruff-0.7.0.ebuild b/dev-ruby/gruff/gruff-0.7.0.ebuild
new file mode 100644
index 000000000000..4e02095ba30e
--- /dev/null
+++ b/dev-ruby/gruff/gruff-0.7.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22"
+
+RUBY_FAKEGEM_TASK_DOC=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="History.txt Manifest.txt README.md RELEASE.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="assets rails_generators"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Beautiful graphs for one or multiple datasets"
+HOMEPAGE="https://github.com/topfunky/gruff"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-macos"
+IUSE=""
+
+# imagemagick is an indirect dependency through rmagick. However, for
+# gruff to work properly imagemagick needs to be compiled with truetype
+# support and this cannot be expressed in the rmagick dependency. Tests
+# also require imagemagick to have jpeg and png support.
+DEPEND="${DEPEND} test? ( media-gfx/imagemagick[jpeg,png,truetype,webp] )"
+RDEPEND="${RDEPEND} media-gfx/imagemagick[truetype]"
+
+ruby_add_rdepend ">=dev-ruby/rmagick-2.13.4"
+ruby_add_bdepend "
+	test? (
+		dev-ruby/hoe
+		dev-ruby/test-unit
+	)"
+
+all_ruby_prepare() {
+	sed -i -e '/reporters/I s:^:#:' test/gruff_test_case.rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
+}