dev-ruby/rack: add 2.0.6

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-ruby/rack/rack-2.0.6.ebuild b/dev-ruby/rack/rack-2.0.6.ebuild
new file mode 100644
index 000000000000..8d62a227634f
--- /dev/null
+++ b/dev-ruby/rack/rack-2.0.6.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="HISTORY.md README.rdoc SPEC"
+
+inherit ruby-fakegem eapi7-ver
+
+DESCRIPTION="A modular Ruby webserver interface"
+HOMEPAGE="https://rack.github.com/"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend "virtual/ruby-ssl"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest:5 dev-ruby/concurrent-ruby )"
+
+# The gem has automagic dependencies over mongrel, ruby-openid,
+# memcache-client, thin, mongrel and camping; not sure if we should
+# make them dependencies at all.
+
+# Block against versions in older slots that also try to install a binary.
+RDEPEND="${RDEPEND} !<dev-ruby/rack-1.4.5-r1:1.4 !<dev-ruby/rack-1.5.2-r4:1.5 !<dev-ruby/rack-1.6.4-r2:1.6"
+
+all_ruby_prepare() {
+	# The build system tries to generate the ChangeLog from git. Create
+	# an empty file to avoid a needless dependency on git.
+	touch ChangeLog || die
+
+	# Avoid development dependency
+	sed -i -e '/minitest-sprint/ s:^:#:' rack.gemspec || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:test:. -e "require 'test/gemloader.rb'; Dir['test/spec_*.rb'].each{|f| require f}" || die
+}