dev-ruby/ruby-clutter: add 3.3.2

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-ruby/ruby-clutter/ruby-clutter-3.3.2.ebuild b/dev-ruby/ruby-clutter/ruby-clutter-3.3.2.ebuild
new file mode 100644
index 000000000000..1e38675c5e7e
--- /dev/null
+++ b/dev-ruby/ruby-clutter/ruby-clutter-3.3.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby23 ruby24 ruby25 ruby26"
+
+inherit virtualx ruby-ng-gnome2
+
+DESCRIPTION="Ruby Clutter bindings"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RUBY_S=ruby-gnome2-all-${PV}/clutter
+
+DEPEND+=" media-libs/clutter"
+RDEPEND+=" media-libs/clutter"
+
+ruby_add_bdepend ">=dev-ruby/ruby-atk-${PV}
+	>=dev-ruby/ruby-gdkpixbuf2-${PV}
+	>=dev-ruby/ruby-glib2-${PV}
+	>=dev-ruby/ruby-gobject-introspection-${PV}
+	>=dev-ruby/ruby-pango-${PV}"
+ruby_add_rdepend ">=dev-ruby/ruby-cairo-gobject-${PV}
+	>=dev-ruby/ruby-gobject-introspection-${PV}
+	>=dev-ruby/ruby-pango-${PV}"
+
+all_ruby_prepare() {
+	# Avoid unneeded dependency on test-unit-notify.
+	sed -i -e '/notify/ s:^:#:' \
+		../gobject-introspection/test/gobject-introspection-test-utils.rb \
+		../cairo-gobject/test/cairo-gobject-test-utils.rb \
+		test/clutter-test-utils.rb || die
+
+	# Avoid compilation of dependencies during test.
+	sed -i -e '/system/,/^  end/ s:^:#:' test/run-test.rb || die
+}
+
+each_ruby_configure() {
+	:
+}
+
+each_ruby_compile() {
+	:
+}
+
+each_ruby_test() {
+	virtx ${RUBY} test/run-test.rb || die
+}
+
+each_ruby_install() {
+	each_fakegem_install
+}