dev-ruby/rubyzip: add 1.2.1

Package-Manager: portage-2.3.3

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-ruby/rubyzip/rubyzip-1.2.1.ebuild b/dev-ruby/rubyzip/rubyzip-1.2.1.ebuild
new file mode 100644
index 000000000000..73d3fc74ccd0
--- /dev/null
+++ b/dev-ruby/rubyzip/rubyzip-1.2.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+USE_RUBY="ruby21 ruby22 ruby23 ruby24"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md TODO"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A ruby library for reading and writing zip files"
+HOMEPAGE="https://github.com/rubyzip/rubyzip"
+# Tests are not included in the gem.
+SRC_URI="https://github.com/rubyzip/rubyzip/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="Ruby"
+SLOT="1"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=""
+DEPEND="${DEPEND} test? ( app-arch/zip )"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest:5 )"
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc samples/*
+}
+
+all_ruby_prepare() {
+	# Avoid dependencies on simplecov and coveralls
+	sed -i -e '/simplecov/ s:^:#:' test/test_helper.rb || die
+
+	# Avoid dependency on bundler
+	sed -i -e '/bundler/ s:^:#:' Rakefile || die
+
+	# Fix hardcoded path to /tmp
+	sed -i -e 's:/tmp/:'${T}'/:g' test/entry_test.rb || die
+
+	# Add missing require
+	sed -i -e '1irequire "forwardable"' test/input_stream_test.rb || die
+}