dev-ruby/test-unit: add 3.3.4

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 33 insertions, 0 deletions

diff --git a/dev-ruby/test-unit/test-unit-3.3.4.ebuild b/dev-ruby/test-unit/test-unit-3.3.4.ebuild
new file mode 100644
index 000000000000..644815042734
--- /dev/null
+++ b/dev-ruby/test-unit/test-unit-3.3.4.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_EXTRADOC="README.md doc-install/text/*.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An xUnit family unit testing framework for Ruby"
+HOMEPAGE="https://rubygems.org/gems/test-unit"
+
+LICENSE="|| ( Ruby GPL-2 ) PSF-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc test"
+
+ruby_add_rdepend "dev-ruby/power_assert"
+
+all_ruby_prepare() {
+	mv doc doc-install || die "moving doc directory out of the way failed"
+}
+
+each_ruby_test() {
+	${RUBY} test/run-test.rb || die "testsuite failed"
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	newbin "${FILESDIR}"/testrb-3 testrb-2
+}