dev-ruby/ruby-opengl: install shared object correctly

Package-Manager: portage-2.2.28

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-ruby/ruby-opengl/ruby-opengl-0.9.2-r1.ebuild b/dev-ruby/ruby-opengl/ruby-opengl-0.9.2-r1.ebuild
new file mode 100644
index 000000000000..705d58ea22ce
--- /dev/null
+++ b/dev-ruby/ruby-opengl/ruby-opengl-0.9.2-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby20 ruby21 ruby22 ruby23"
+
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Two tests fails but the README already indicates that this may not
+# work. Additionally these tests require access to video devices such as
+# /dev/nvidiactl.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_NAME="opengl"
+
+RUBY_FAKEGEM_EXTRADOC="History.rdoc README.rdoc"
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="OpenGL / GLUT bindings for ruby"
+HOMEPAGE="https://github.com/larskanis/opengl"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+
+IUSE=""
+
+DEPEND+=" virtual/opengl
+	media-libs/freeglut"
+RDEPEND+=" virtual/opengl
+	media-libs/freeglut"
+
+each_ruby_configure() {
+	${RUBY} -Cext/opengl extconf.rb || die
+}
+
+each_ruby_compile() {
+	emake -C ext/opengl V=1
+
+	cp ext/*/*$(get_modname) lib/opengl/ || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/examples
+	doins -r examples/*
+}