dev-util/devhelp: Version bump to 43.0

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-util/devhelp/Manifest b/dev-util/devhelp/Manifest
index 98bd8fd423b8..fddd82c226f6 100644
--- a/dev-util/devhelp/Manifest
+++ b/dev-util/devhelp/Manifest
@@ -1,2 +1,3 @@
 DIST devhelp-41.2.tar.xz 1455736 BLAKE2B c531af6cded6c9624581e4d14fb4d7713afbdcf173ec2a82e49789af1752568790dc346cc0293eddc68c0943fec4f742de726953de34441771711a938ba858fa SHA512 99a75ff19bf1b4613c312921452f190334e3e2036c28cda070169e3d1d352a5d2e7a56a393326efd679076257412e281dc94b628429119fcad58060d1a88ea98
 DIST devhelp-41.3.tar.xz 2303068 BLAKE2B 1c08931897a7cd1d15028d9394479297d6fffc48412aa31cc739380405b8588fec47fddbea803c80d44eb23d2fa84d5f9a42aa8b061859d459e450ccd76ee82d SHA512 91251f1d8c0380f16768a1fed2d0a0a19935a646613a966c48ae70e52bfe8b6aa0c683d2b371d9e25dfdfcaeac687ea2c83c2bfd5f4f35394bb4576e6f98b48d
+DIST devhelp-43.0.tar.xz 327508 BLAKE2B 455015ec115610f27c2a1d9c3a8a21f50d8b061de7524371d892aba35173278f3aabe623b0b6770437b1501e6af795a9a12c9cc3ae238d8691d00e27388ae1a4 SHA512 92f147659754480ac4aa02f21558572d4bb8a034251225d344a8cae16824d9c14071751dfca6439f98dc7f7884fb35ef2d9c708e42f11bb6b3dfd8648b784654
diff --git a/dev-util/devhelp/devhelp-43.0.ebuild b/dev-util/devhelp/devhelp-43.0.ebuild
new file mode 100644
index 000000000000..481ad3bd226d
--- /dev/null
+++ b/dev-util/devhelp/devhelp-43.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-3+ CC-BY-SA-4.0"
+SLOT="0/3-6" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~amd64 ~arm ~ppc64 ~sparc ~x86"
+IUSE="+gedit gtk-doc +introspection"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} ) gtk-doc? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.64:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	net-libs/webkit-gtk:4.1[introspection?]
+	gnome-base/gsettings-desktop-schemas
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			app-editors/gedit[introspection(+),python,${PYTHON_SINGLE_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+		')
+	)
+"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	dev-util/itstool
+	gtk-doc? ( >=dev-util/gi-docgen-2021.6 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/41.2-optional-introspection.patch
+)
+
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dflatpak_build=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dplugin_emacs=true
+		$(meson_use gedit plugin_gedit)
+		-Dplugin_vim=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/devhelp-3 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+	use gedit && python_optimize "${ED}"/usr/$(get_libdir)/gedit/plugins
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}