version bump with some fixes

This commit add a multiple python version support to address python3
installtion issue. (based on a patch from Holger Hoffstätte
<holger@applied-asynchrony.com>)

Also, this commit add a patch to build with >=sys-devel/clang-9. (patch
from Maciej S. Szmigiero <mail@maciej.szmigiero.name> and Dennis
Schridde <devurandom@gmx.net>).

Closes: https://bugs.gentoo.org/679762
Closes: https://bugs.gentoo.org/695726
Signed-off-by: Naohiro Aota <naota@gentoo.org>

3 files changed, 265 insertions, 0 deletions

diff --git a/dev-util/perf/Manifest b/dev-util/perf/Manifest
index 012d83314549..14e8bf98547c 100644
--- a/dev-util/perf/Manifest
+++ b/dev-util/perf/Manifest
@@ -1,6 +1,8 @@
 DIST linux-4.14.tar.xz 100770500 BLAKE2B 85dc4aa953fe65e273a24473d8de98e4f204f97c43be9fc87cf5be01f796f94cfde5c8f9c84619751f1cac51f83ce0b4681fb19c5f2965a72d4a94fe5577846a SHA512 77e43a02d766c3d73b7e25c4aafb2e931d6b16e870510c22cef0cdb05c3acb7952b8908ebad12b10ef982c6efbe286364b1544586e715cf38390e483927904d8
 DIST linux-4.20.tar.xz 104257836 BLAKE2B fb52cad2897da319299486fa8c3b9415cd0aee0842dbf353a5b269720dcb902db407bb55dd95a77b212dcb4a488c15363d561f3649d6bd16885561f2466d90b1 SHA512 e282399beea5da539701aed2bc131abd5bc74a970dcd344163e9d295106dfd700180e672ed546ae5e55bc6b9ac95efd5ca1de2039015c1b7a6fc9c01ea6583d4
 DIST linux-5.3.tar.xz 108558876 BLAKE2B 0d08eed879d05734e4542f0c93823d43f8dc042a54ba5268064c4bbebd7a9d59c03abf3ad5dee8280e784ae148a3b0c56181eaf2d5b3c079b6fe9f5191544df6 SHA512 6b5edef47c319a3fa7f6c20a3e0903a5acd89ec75e32dc5f99adcb60c9fe118ea312722d9c3d27e2e3900afa2455afb86e83a8b6bb131009bc79ddbe6fb0595d
+DIST linux-5.4.tar.xz 109441440 BLAKE2B 193bc4a3147e147d5529956164ec4912fad5d5c6fb07f909ff1056e57235834173194afc686993ccd785c1ff15804de0961b625f3008cca0e27493efc8f27b13 SHA512 9f60f77e8ab972b9438ac648bed17551c8491d6585a5e85f694b2eaa4c623fbc61eb18419b2656b6795eac5deec0edaa04547fc6723fbda52256bd7f3486898f
 DIST patch-4.14.33.xz 905284 BLAKE2B e67bd9a96708aaaf65eb0aa852493b2323c9e237bfcc6fa837f795e481943ead3e2d5005ee72e40fc247df01c50877d9da3848a05aba3c999c3cfb7678cbdbc9 SHA512 5c76be5171709c2df7df7d5a8e8f3d0f7ede47b433da3b0f1710f262c8fcf5cf6c744a96d4336ea397c2c88a5f0a7507a5ab08c7c82f08deeb7a6f887ad77cfd
 DIST patch-4.20.3.xz 91732 BLAKE2B bf99271bcb35508df239343fd6c9d57c246f88320b586e44e2d97771d08b249a24db230214d4957015a5ed35261e201f0680101b99d0e92f0f1f69bc53e21458 SHA512 47178b8e3bfe4ba09cb82bb1ce8b0742e6749d4be3412fb57518918f7109e74eac1d3d8eb32a43e21b3837a14f37d5eefd8cab819defd10cc2db61fb0ceddeaf
 DIST patch-5.3.7.xz 255616 BLAKE2B 18ec40508fdb2cc17dd927f3ddef07b2b744ff993de75bb7adebe3a3f97c9383ea1845085899aa939ca8a15515420c18a1ac0ae832f9ae52f18cc8ed59a1e75f SHA512 bf2717b721b3acfd423537a6a520388e6a596ae65605ed8c029a67c117a002e9a21c324de0dd41407bfdc8ef95263687764f4f46aa59cbb50f68ab21b96c29d6
+DIST patch-5.4.6.xz 167272 BLAKE2B 43d7b0b7ee412f68eceb3be32d2629d1a5effef127b3351a499463a740809bdd7274c1ec409bbd77b203b2e4ef117c5c390b4d4b6a440385ab91ee9dcac74926 SHA512 6f6d73c7ce71d47e810847149f4c258f5fb99c98fc67d385a3ff74889543a415bf8bb77c748a13f72b733bca770773731d84713a9be98d630b7377a792f11f5a
diff --git a/dev-util/perf/files/perf-5.4.6-fix-clang9.patch b/dev-util/perf/files/perf-5.4.6-fix-clang9.patch
new file mode 100644
index 000000000000..614e62f676d2
--- /dev/null
+++ b/dev-util/perf/files/perf-5.4.6-fix-clang9.patch
@@ -0,0 +1,17 @@
+https://bugs.gentoo.org/695726
+Created-By: Maciej S. Szmigiero <mail@maciej.szmigiero.name>
+Created-By: Dennis Schridde <devurandom@gmx.net>
+--- a/tools/perf/util/c++/clang.cpp.orig	2019-12-20 16:39:21.015363866 +0100
++++ b/tools/perf/util/c++/clang.cpp	2019-12-20 16:40:04.051639185 +0100
+@@ -71,7 +71,11 @@
+ 	CompilerInstance Clang;
+ 	Clang.createDiagnostics();
+ 
++#if CLANG_VERSION_MAJOR < 9
+ 	Clang.setVirtualFileSystem(&*VFS);
++#else
++	Clang.createFileManager(&*VFS);
++#endif
+ 
+ #if CLANG_VERSION_MAJOR < 4
+ 	IntrusiveRefCntPtr<CompilerInvocation> CI =
diff --git a/dev-util/perf/perf-5.4.6.ebuild b/dev-util/perf/perf-5.4.6.ebuild
new file mode 100644
index 000000000000..8fb6d4668691
--- /dev/null
+++ b/dev-util/perf/perf-5.4.6.ebuild
@@ -0,0 +1,246 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit bash-completion-r1 estack eutils toolchain-funcs python-r1 linux-info
+
+MY_PV="${PV/_/-}"
+MY_PV="${MY_PV/-pre/-git}"
+
+DESCRIPTION="Userland tools for Linux Performance Counters"
+HOMEPAGE="https://perf.wiki.kernel.org/"
+
+LINUX_V="${PV:0:1}.x"
+if [[ ${PV} == *_rc* ]] ; then
+	LINUX_VER=$(ver_cut 1-2).$(($(ver_cut 3)-1))
+	PATCH_VERSION=$(ver_cut 1-3)
+	LINUX_PATCH=patch-${PV//_/-}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/${LINUX_PATCH}
+		https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/testing/v${PATCH_VERSION}/${LINUX_PATCH}"
+elif [[ ${PV} == *.*.* ]] ; then
+	# stable-release series
+	LINUX_VER=$(ver_cut 1-2)
+	LINUX_PATCH=patch-${PV}.xz
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_PATCH}"
+else
+	LINUX_VER=${PV}
+	SRC_URI=""
+fi
+
+LINUX_SOURCES="linux-${LINUX_VER}.tar.xz"
+SRC_URI+=" https://www.kernel.org/pub/linux/kernel/v${LINUX_V}/${LINUX_SOURCES}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="audit clang crypt debug +demangle +doc gtk java lzma numa perl python slang systemtap unwind zlib"
+# TODO babeltrace
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="audit? ( sys-process/audit )
+	crypt? ( dev-libs/openssl:0= )
+	clang? (
+		sys-devel/clang:*
+		sys-devel/llvm:*
+	)
+	demangle? ( sys-libs/binutils-libs:= )
+	gtk? ( x11-libs/gtk+:2 )
+	java? ( virtual/jre:* )
+	lzma? ( app-arch/xz-utils )
+	numa? ( sys-process/numactl )
+	perl? ( dev-lang/perl:= )
+	python? ( ${PYTHON_DEPS} )
+	slang? ( sys-libs/slang )
+	systemtap? ( dev-util/systemtap )
+	unwind? ( sys-libs/libunwind )
+	zlib? ( sys-libs/zlib )
+	dev-libs/elfutils"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-4.19
+	${LINUX_PATCH+dev-util/patchutils}
+	sys-devel/bison
+	sys-devel/flex
+	java? ( virtual/jdk )
+	doc? (
+		app-text/asciidoc
+		app-text/sgml-common
+		app-text/xmlto
+		sys-process/time
+	)"
+
+S_K="${WORKDIR}/linux-${LINUX_VER}"
+S="${S_K}/tools/perf"
+
+CONFIG_CHECK="~PERF_EVENTS ~KALLSYMS"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	use python && python-r1_pkg_setup
+}
+
+src_unpack() {
+	local paths=(
+		tools/arch tools/build tools/include tools/lib tools/perf tools/scripts
+		include lib "arch/*/lib"
+	)
+
+	# We expect the tar implementation to support the -j option (both
+	# GNU tar and libarchive's tar support that).
+	echo ">>> Unpacking ${LINUX_SOURCES} (${paths[*]}) to ${PWD}"
+	tar --wildcards -xpf "${DISTDIR}"/${LINUX_SOURCES} \
+		"${paths[@]/#/linux-${LINUX_VER}/}" || die
+
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		eshopts_push -o noglob
+		ebegin "Filtering partial source patch"
+		filterdiff -p1 ${paths[@]/#/-i } -z "${DISTDIR}"/${LINUX_PATCH} \
+			> ${P}.patch
+		eend $? || die "filterdiff failed"
+		eshopts_pop
+	fi
+
+	local a
+	for a in ${A}; do
+		[[ ${a} == ${LINUX_SOURCES} ]] && continue
+		[[ ${a} == ${LINUX_PATCH} ]] && continue
+		unpack ${a}
+	done
+
+	# support clang8
+	echo $(clang-major-version)
+	if use clang; then
+		local old_CC=${CC}
+		CC=${CHOST}-clang
+		if [[ $(clang-major-version) -ge 8 ]]; then
+			pushd "${S_K}" >/dev/null || die
+			eapply \
+				"${FILESDIR}/perf-5.1.15-fix-clang8.patch" \
+				"${FILESDIR}/perf-5.4.6-fix-clang9.patch"
+			popd || die
+		fi
+		CC=${old_CC}
+	fi
+}
+
+src_prepare() {
+	default
+	if [[ -n ${LINUX_PATCH} ]] ; then
+		pushd "${S_K}" >/dev/null || die
+		eapply "${WORKDIR}"/${P}.patch
+		popd || die
+	fi
+
+	# Drop some upstream too-developer-oriented flags and fix the
+	# Makefile in general
+	sed -i \
+		-e "s:\$(sysconfdir_SQ)/bash_completion.d:$(get_bashcompdir):" \
+		"${S}"/Makefile.perf || die
+	# A few places still use -Werror w/out $(WERROR) protection.
+	sed -i -e 's:-Werror::' \
+		"${S}"/Makefile.perf "${S_K}"/tools/lib/bpf/Makefile || die
+
+	# Avoid the call to make kernelversion
+	echo "#define PERF_VERSION \"${MY_PV}\"" > PERF-VERSION-FILE
+
+	# The code likes to compile local assembly files which lack ELF markings.
+	find -name '*.S' -exec sed -i '$a.section .note.GNU-stack,"",%progbits' {} +
+}
+
+puse() { usex $1 "" no; }
+perf_make() {
+	# The arch parsing is a bit funky.  The perf tools package is integrated
+	# into the kernel, so it wants an ARCH that looks like the kernel arch,
+	# but it also wants to know about the split value -- i386/x86_64 vs just
+	# x86.  We can get that by telling the func to use an older linux version.
+	# It's kind of a hack, but not that bad ...
+
+	# LIBDIR sets a search path of perf-gtk.so. Bug 515954
+
+	local arch=$(tc-arch-kernel)
+	local java_dir
+	use java && java_dir="/etc/java-config-2/current-system-vm"
+	# FIXME: NO_CORESIGHT
+	# FIXME: NO_LIBBABELTRACE
+	emake V=1 VF=1 \
+		CC="$(tc-getCC)" CXX="$(tc-getCXX)" AR="$(tc-getAR)" LD="$(tc-getLD)" \
+		prefix="${EPREFIX}/usr" bindir_relative="bin" \
+		EXTRA_CFLAGS="${CFLAGS}" \
+		ARCH="${arch}" \
+		JDIR="${java_dir}" \
+		LIBCLANGLLVM=$(usex clang 1 "") \
+		NO_AUXTRACE="" \
+		NO_BACKTRACE="" \
+		NO_CORESIGHT=1 \
+		NO_DEMANGLE=$(puse demangle) \
+		NO_GTK2=$(puse gtk) \
+		NO_JVMTI=$(puse java) \
+		NO_LIBAUDIT=$(puse audit) \
+		NO_LIBBABELTRACE=1 \
+		NO_LIBBIONIC=1 \
+		NO_LIBBPF="" \
+		NO_LIBCRYPTO=$(puse crypt) \
+		NO_LIBDW_DWARF_UNWIND="" \
+		NO_LIBELF="" \
+		NO_LIBNUMA=$(puse numa) \
+		NO_LIBPERL=$(puse perl) \
+		NO_LIBPYTHON=$(puse python) \
+		NO_LIBUNWIND=$(puse unwind) \
+		NO_SDT=$(puse systemtap) \
+		NO_SLANG=$(puse slang) \
+		NO_LZMA=$(puse lzma) \
+		NO_ZLIB= \
+		WERROR=0 \
+		LIBDIR="/usr/libexec/perf-core" \
+		"$@"
+}
+
+src_compile() {
+	# test-clang.bin not build with g++
+	if use clang; then
+		pushd "${S_K}/tools/build/feature/" || die
+		make V=1 CXX=${CHOST}-clang++ test-clang.bin || die
+		popd
+	fi
+	perf_make -f Makefile.perf
+	use doc && perf_make -C Documentation
+}
+
+src_test() {
+	:
+}
+
+src_install() {
+	_install_python_ext() {
+		perf_make -f Makefile.perf install-python_ext DESTDIR="${D}"
+	}
+
+	perf_make -f Makefile.perf install DESTDIR="${D}"
+	if python; then
+		python_foreach_impl _install_python_ext
+	fi
+
+	rm -rv "${ED}"/usr/share/doc/perf-tip || die
+
+	if use gtk; then
+		mv "${ED}"/usr/$(get_libdir)/libperf-gtk.so \
+			"${ED}"/usr/libexec/perf-core || die
+	fi
+
+	dodoc CREDITS
+
+	dodoc *txt Documentation/*.txt
+	if use doc ; then
+		HTML_DOCS="Documentation/*.html" einstalldocs
+		doman Documentation/*.1
+	fi
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Without the doc USE flag you won't get any documentation nor man pages."
+		elog "And without man pages, you won't get any --help output for perf and its"
+		elog "sub-tools."
+	fi
+}