summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSergei Trofimovich <slyfox@gentoo.org>2019-02-20 21:42:16 +0000
committerSergei Trofimovich <slyfox@gentoo.org>2019-02-20 21:42:30 +0000
commit5cce0aa7dd47af4d8d719cafb8fb0e40cb0890b2 (patch)
tree9dca4aec512594962cc23e5633845b69c10ca56c /dev-util/radare2/radare2-3.3.0.ebuild
parentsys-cluster/keepalived: Version bump (v2.0.13) (diff)
downloadgentoo-5cce0aa7dd47af4d8d719cafb8fb0e40cb0890b2.tar.gz
gentoo-5cce0aa7dd47af4d8d719cafb8fb0e40cb0890b2.tar.bz2
gentoo-5cce0aa7dd47af4d8d719cafb8fb0e40cb0890b2.zip
dev-util/radare2: bump up to 3.3.0
Package-Manager: Portage-2.3.61, Repoman-2.3.12 Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
Diffstat (limited to 'dev-util/radare2/radare2-3.3.0.ebuild')
-rw-r--r--dev-util/radare2/radare2-3.3.0.ebuild56
1 files changed, 56 insertions, 0 deletions
diff --git a/dev-util/radare2/radare2-3.3.0.ebuild b/dev-util/radare2/radare2-3.3.0.ebuild
new file mode 100644
index 00000000000..0b3f4cfb432
--- /dev/null
+++ b/dev-util/radare2/radare2-3.3.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1 eutils
+
+DESCRIPTION="unix-like reverse engineering framework and commandline tools"
+HOMEPAGE="http://www.radare.org"
+
+if [[ ${PV} == *9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/radare/radare2"
+else
+ SRC_URI="https://github.com/radare/radare2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ssl libressl"
+
+RDEPEND="
+ dev-libs/capstone:0=
+ ssl? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+ econf \
+ --without-libuv \
+ --with-syscapstone \
+ $(use_with ssl openssl)
+}
+
+src_install() {
+ default
+
+ insinto /usr/share/zsh/site-functions
+ doins doc/zsh/_*
+
+ newbashcomp doc/bash_autocompletion.sh "${PN}"
+ bashcomp_alias "${PN}" rafind2 r2 rabin2 rasm2 radiff2
+
+ # a workaround for unstable $(INSTALL) call, bug #574866
+ local d
+ for d in doc/*; do
+ if [[ -d $d ]]; then
+ rm -rfv "$d" || die "failed to delete '$d'"
+ fi
+ done
+}