dev-util/redo: Versions 0.31 99999

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-util/redo/redo-99999.ebuild b/dev-util/redo/redo-99999.ebuild
new file mode 100644
index 000000000000..44c936cb5309
--- /dev/null
+++ b/dev-util/redo/redo-99999.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+inherit git-r3 multilib multiprocessing python-single-r1
+
+DESCRIPTION="Smaller, easier, more powerful, and more reliable than make"
+HOMEPAGE="https://github.com/apenwarr/redo"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS=""
+DEPEND="
+	dev-python/beautifulsoup[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+"
+
+src_compile() {
+	./redo -j$(makeopts_jobs) || die
+}
+
+src_test() {
+	./redo -j$(makeopts_jobs) test || die
+}
+
+src_install() {
+	DESTDIR="${D}" \
+	DOCDIR="${D}/usr/share/doc/${PF}" \
+	LIBDIR="${D}/usr/$(get_libdir)/${PN}" \
+	./redo -j$(makeopts_jobs) \
+		install || die
+
+	python_fix_shebang "${D}"
+
+	sed -i \
+		-e 's|/lib/|/'"$(get_libdir)"'/|g' \
+		"${D}"/usr/bin/* || die
+}