dev-util/xdelta: Bump to 3.0.11

1 files changed, 42 insertions, 0 deletions

diff --git a/dev-util/xdelta/xdelta-3.0.11.ebuild b/dev-util/xdelta/xdelta-3.0.11.ebuild
new file mode 100644
index 000000000000..53f2f26dd630
--- /dev/null
+++ b/dev-util/xdelta/xdelta-3.0.11.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+MY_P=xdelta3-${PV}
+
+DESCRIPTION="a binary diff and differential compression tools. VCDIFF (RFC 3284) delta compression"
+HOMEPAGE="http://xdelta.org/"
+SRC_URI="https://github.com/jmacd/xdelta-gpl/releases/download/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="examples lzma test"
+
+RDEPEND="lzma? ( app-arch/xz-utils:= )"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	econf \
+		$(use_with lzma liblzma)
+}
+
+src_compile() {
+	# avoid building tests
+	emake xdelta3
+}
+
+src_test() {
+	emake xdelta3regtest
+	./xdelta3regtest || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install-binPROGRAMS install-man1
+	dodoc draft-korn-vcdiff.txt README.md
+	use examples && dodoc -r examples
+}