dev-vcs/tortoisehg: 6.2 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
Closes: https://github.com/gentoo/gentoo/pull/26501
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

3 files changed, 83 insertions, 3 deletions

diff --git a/dev-vcs/tortoisehg/Manifest b/dev-vcs/tortoisehg/Manifest
index eebc2408043b..11fbded3836e 100644
--- a/dev-vcs/tortoisehg/Manifest
+++ b/dev-vcs/tortoisehg/Manifest
@@ -3,3 +3,4 @@ DIST tortoisehg-5.9.1.tar.gz 8637928 BLAKE2B 57687359eb00018a811e28449dccce26056
 DIST tortoisehg-5.9.3.tar.gz 8637453 BLAKE2B 9fa90c108f32b1e15c233e7ccbadbda08e434f23aa5c5fe7c235c743c98f54f4222a1804c06b0ca300cc3d0b049c117007a53452ff20ae4411bca30d8ed9013b SHA512 870b3b717962b8450d07fca5300f971d187236edce5a9d2926144b832c0771b8f5a324bdfd05a1fed3d2b4de4bad913c0c8f4435908e602e268c561ed64abbb2
 DIST tortoisehg-6.1.tar.gz 8651661 BLAKE2B 0b66c057973eeef443370151884205144d75a7f21f3f3af5521ba43c2e366cc28c52850ddd7eec6e33ba97236fca99e63fdf9c0eb570213f382d726e63837217 SHA512 98b2d1c357f0996f8e2ef9e2440fe005e28672effe8a871a2bf940a973cbba9f49afb234eb28d4d9b3a15bad4bedd61d302e975787e76f9abd52f5958a7a219f
 DIST tortoisehg-6.1.2.tar.gz 8676222 BLAKE2B 08f8ed7e17ebf9223b91496a5a7ca90f11d1c859d82c5ec7ad714690fe4bb00ac96d89cd7552cba0215b505604688bae875d59e3efe5cde64a26baf331e6301a SHA512 baadb018a0e426a83b7be484834c336099e8969711bc6b6752e98262b88ea5ff3fab7dbb13fe9622e4823f719f008ca0ee599823e65253c7c7741efb0f796558
+DIST tortoisehg-6.2.tar.gz 8876113 BLAKE2B e6840c6c3e6f0dc19e06313644072c21d28ee59a7f5d7b3b4114b643ef4a013375df8f27ce8ad8e7a2ba49d4086ea46e249fc3bda63b217940bc6e9deea2b0e0 SHA512 1a63d4ed92887c6dc4fef153c6dc8c054c5927c0e3b92b26e6a7782af4438cf4f4c83271c0a037fb107538f781d26a765937197658b8250df3735e39a0194344
diff --git a/dev-vcs/tortoisehg/tortoisehg-6.2.ebuild b/dev-vcs/tortoisehg/tortoisehg-6.2.ebuild
new file mode 100644
index 000000000000..d1fbe12fabfd
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-6.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature xdg-utils
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	SRC_URI="https://foss.heptapod.net/mercurial/${PN}/thg/-/archive/${PV}/thg-${PV}.tar.gz -> ${P}.tar.gz"
+	HG_DEPEND=">=dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]
+		<dev-vcs/mercurial-6.3[${PYTHON_USEDEP}]"
+	S="${WORKDIR}/thg-${PV}"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://foss.heptapod.net/mercurial/${PN}/thg"
+	EHG_REVISION="stable"
+	HG_DEPEND=">=dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${HG_DEPEND}
+	dev-python/iniparse[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
+	>=dev-python/qscintilla-python-2.11.6[qt5(+),${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc/source
+
+python_prepare_all() {
+	# Remove file that collides with >=mercurial-4.0 (bug #599266).
+	rm "${S}"/hgext3rd/__init__.py || die "can't remove /hgext3rd/__init__.py"
+
+	sed -i -e 's:share/doc/tortoisehg:share/doc/'"${PF}"':' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	${EPYTHON} tests/run-tests.py -m 'not largefiles' --disable-pytest-warnings --doctest-modules tests || die "Tests failed with ${EPYTHON}"
+	${EPYTHON} tests/run-tests.py -m largefiles --disable-pytest-warnings tests || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+	newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+	domenu contrib/thg.desktop
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	elog "When startup of ${PN} fails with an API version mismatch error"
+	elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+	elog "dev-python/qscintilla-python."
+
+	optfeature "the core git extension support" dev-python/pygit2
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/dev-vcs/tortoisehg/tortoisehg-9999.ebuild b/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
index fbf56b913fc3..56fb962cbc28 100644
--- a/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
+++ b/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
@@ -4,7 +4,6 @@
 EAPI=8
 
 PYTHON_COMPAT=( python3_{8..10} )
-
 DISTUTILS_USE_SETUPTOOLS=no
 
 inherit desktop distutils-r1 optfeature xdg-utils
@@ -13,7 +12,7 @@ if [[ ${PV} != *9999* ]]; then
 	KEYWORDS="~amd64 ~arm64 ~x86"
 	SRC_URI="https://foss.heptapod.net/mercurial/${PN}/thg/-/archive/${PV}/thg-${PV}.tar.gz -> ${P}.tar.gz"
 	HG_DEPEND=">=dev-vcs/mercurial-5.9[${PYTHON_USEDEP}]
-		<dev-vcs/mercurial-6.2[${PYTHON_USEDEP}]"
+		<dev-vcs/mercurial-6.3[${PYTHON_USEDEP}]"
 	S="${WORKDIR}/thg-${PV}"
 else
 	inherit mercurial
@@ -35,7 +34,7 @@ RDEPEND="
 	dev-python/iniparse[${PYTHON_USEDEP}]
 	dev-python/pygments[${PYTHON_USEDEP}]
 	dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
-	>=dev-python/qscintilla-python-2.9.4[qt5(+),${PYTHON_USEDEP}]
+	>=dev-python/qscintilla-python-2.11.6[qt5(+),${PYTHON_USEDEP}]
 "
 DEPEND="
 	${RDEPEND}