proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 72 insertions, 0 deletions

diff --git a/gnome-extra/cinnamon-session/cinnamon-session-2.4.3.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-2.4.3.ebuild
new file mode 100644
index 000000000000..9ebfeb69fc0d
--- /dev/null
+++ b/gnome-extra/cinnamon-session/cinnamon-session-2.4.3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit autotools eutils gnome2
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="http://cinnamon.linuxmint.com/"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc ipv6 systemd"
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.76
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/json-glib-0.10
+	media-libs/libcanberra
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-2.90.7:3
+	x11-libs/cairo
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	virtual/opengl
+	systemd? ( >=sys-apps/systemd-183 )
+	!systemd? ( >=sys-power/upower-pm-utils-0.9.23 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!systemd? ( sys-auth/consolekit )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	>=dev-util/intltool-0.40.6
+	virtual/pkgconfig
+	doc? ( app-text/xmlto )
+
+	gnome-base/gnome-common
+"
+#	gnome-base/gnome-common for eautoreconf
+
+src_prepare() {
+	# make upower check non-automagic
+	epatch "${FILESDIR}/${PN}-2.2.0-automagic-upower.patch"
+	epatch_user
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS README README.md"
+
+	gnome2_src_configure \
+		--disable-gconf \
+		--disable-static \
+		$(use_enable doc docbook-docs) \
+		$(use_enable ipv6) \
+		$(use_enable systemd) \
+		$(usex systemd --disable-old-upower --enable-old-upower)
+}