gnome-extra/cinnamon-session: Rely on IUSE=elogind for non-systemd

There are (probably obsolete) deps on polkit[elogind] for non-systemd
case, which is a problem now that we use.mask elogind on systemd
profiles. No-one hits this problem in practice (as elogind users
don't have systemd profiles active), but the CI and repoman trips up
on this.
Rework this into a REQUIRED_USE="^^ ( elogind systemd )" like in
other packages, until this polkit dep is there, to make repoman happy.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 70 insertions, 0 deletions

diff --git a/gnome-extra/cinnamon-session/cinnamon-session-3.6.1-r5.ebuild b/gnome-extra/cinnamon-session/cinnamon-session-3.6.1-r5.ebuild
new file mode 100644
index 000000000000..a3760072b6df
--- /dev/null
+++ b/gnome-extra/cinnamon-session/cinnamon-session-3.6.1-r5.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils gnome2
+
+DESCRIPTION="Cinnamon session manager"
+HOMEPAGE="http://cinnamon.linuxmint.com/"
+SRC_URI="https://github.com/linuxmint/cinnamon-session/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc elogind ipv6 systemd"
+REQUIRED_USE="^^ ( elogind systemd )"
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.88
+	>=dev-libs/glib-2.37.3:2
+	media-libs/libcanberra
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3:3
+	x11-libs/cairo
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXext
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango[X]
+	virtual/opengl
+	systemd? ( >=sys-apps/systemd-183
+			   sys-auth/polkit )
+	elogind? ( sys-power/upower
+			   sys-auth/polkit[elogind] )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-extra/cinnamon-desktop-2.6[systemd=]
+	elogind? ( sys-auth/elogind[policykit] )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	>=dev-util/intltool-0.40.6
+	virtual/pkgconfig
+	doc? ( app-text/xmlto )
+
+	gnome-base/gnome-common
+"
+
+src_prepare() {
+	# make upower and logind check non-automagic
+	eapply "${FILESDIR}/${PN}-3.0.1-automagic.patch"
+	eapply "${FILESDIR}/${PN}-3.6.1-elogind.patch"
+	eapply "${FILESDIR}/${PN}-3.6.1-elogind2.patch"
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-gconf \
+		--disable-static \
+		--enable-logind \
+		$(use_enable doc docbook-docs) \
+		$(use_enable ipv6)
+}