summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorGilles Dartiguelongue <eva@gentoo.org>2017-12-17 23:47:44 +0100
committerGilles Dartiguelongue <eva@gentoo.org>2017-12-18 00:13:33 +0100
commite2e45385831a5bc622c94f0405d66dc9de2f6165 (patch)
tree582798572a206ba0d4464e313cc8649dceb5bcab /gnome-extra/gucharmap/gucharmap-10.0.3.ebuild
parentx11-libs/gdk-pixbuf: drop old revision (diff)
downloadgentoo-e2e45385831a5bc622c94f0405d66dc9de2f6165.tar.gz
gentoo-e2e45385831a5bc622c94f0405d66dc9de2f6165.tar.bz2
gentoo-e2e45385831a5bc622c94f0405d66dc9de2f6165.zip
gnome-extra/gucharmap: version bump 10.0.0 → 10.0.2
Translation updates. Package-Manager: Portage-2.3.19, Repoman-2.3.6
Diffstat (limited to 'gnome-extra/gucharmap/gucharmap-10.0.3.ebuild')
-rw-r--r--gnome-extra/gucharmap/gucharmap-10.0.3.ebuild63
1 files changed, 63 insertions, 0 deletions
diff --git a/gnome-extra/gucharmap/gucharmap-10.0.3.ebuild b/gnome-extra/gucharmap/gucharmap-10.0.3.ebuild
new file mode 100644
index 00000000000..b701e7d0a46
--- /dev/null
+++ b/gnome-extra/gucharmap/gucharmap-10.0.3.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala versionator
+
+DESCRIPTION="Unicode character map viewer and library"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gucharmap"
+
+LICENSE="GPL-3"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+
+IUSE="debug +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+UNICODE_VERSION=$(get_version_component_range 1-2)
+
+COMMON_DEPEND="
+ =app-i18n/unicode-data-${UNICODE_VERSION}*
+ >=dev-libs/glib-2.32:2
+ >=x11-libs/pango-1.2.1[introspection?]
+ >=x11-libs/gtk+-3.16:3[introspection?]
+ introspection? ( >=dev-libs/gobject-introspection-0.9.0:= )
+"
+RDEPEND="${COMMON_DEPEND}
+ !<gnome-extra/gucharmap-3:0
+"
+DEPEND="${RDEPEND}
+ app-text/yelp-tools
+ dev-util/desktop-file-utils
+ >=dev-util/gtk-doc-am-1
+ >=dev-util/intltool-0.40
+ sys-devel/gettext
+ virtual/pkgconfig
+ test? ( app-text/docbook-xml-dtd:4.1.2 )
+ vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+ # prevent file collisions with slot 0
+ sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
+ -i configure.ac configure || die "sed configure.ac configure failed"
+
+ # avoid autoreconf
+ sed -e 's/-Wall //g' -i configure || die "sed failed"
+
+ use vala && vala_src_prepare
+ gnome2_src_prepare
+}
+
+src_configure() {
+ # unihan is not really conditional
+ # https://bugzilla.gnome.org/show_bug.cgi?id=768210#c5
+ gnome2_src_configure \
+ --disable-static \
+ --with-unicode-data=/usr/share/unicode-data \
+ $(usex debug --enable-debug=yes ' ') \
+ $(use_enable introspection) \
+ $(use_enable vala)
+}