summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMart Raudsepp <leio@gentoo.org>2019-03-22 12:29:19 +0200
committerMart Raudsepp <leio@gentoo.org>2019-03-22 14:17:17 +0200
commitbe94f5d3b17fd609fe3381a9c8e695c178b3d8e5 (patch)
treee50919dc35f80de3237f26c9d9a4e332c2ee2941 /gnome-extra
parentgnome-extra/gnome-software: ebuild touchups (diff)
downloadgentoo-be94f5d3b17fd609fe3381a9c8e695c178b3d8e5.tar.gz
gentoo-be94f5d3b17fd609fe3381a9c8e695c178b3d8e5.tar.bz2
gentoo-be94f5d3b17fd609fe3381a9c8e695c178b3d8e5.zip
gnome-extra/gnome-software: bump to 3.30.6, conditional packagekit
packagekit is "not ready for primetime" and even use.masked, so I don't think we should force it on gnome-software when gnome-software can be useful for upgrading device firmware, handle shell extensions and (eventually) flatpaks. Also default-enable USE=firmware to have firmware upgrades show up, some of which may be security relevant (e.g. logitech unifying receiver firmware updates). Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Mart Raudsepp <leio@gentoo.org>
Diffstat (limited to 'gnome-extra')
-rw-r--r--gnome-extra/gnome-software/Manifest1
-rw-r--r--gnome-extra/gnome-software/gnome-software-3.30.6.ebuild101
-rw-r--r--gnome-extra/gnome-software/metadata.xml1
3 files changed, 103 insertions, 0 deletions
diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 75552fe0c0d..6ede4bf38a9 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1,2 +1,3 @@
DIST gnome-software-3.22.7.tar.xz 3865764 BLAKE2B c23e3b9e34a9b233a584a920fcd5969b3ebb5fa4227da147870e71c1531da6c3efda913149a903667ae1725c505c1c842aac0a76b439a2730bf6c837f39757fc SHA512 184714710695d8c48451c1ee7885524dfa30cc6091975bdd317bdd6ce130e7815ab7474074ed191913594bcd5142932bd7918ae19a695170a34a5f934e1b9825
DIST gnome-software-3.28.2.tar.xz 5181868 BLAKE2B 4744ff13216ac1421700ef9c5ec9fb540ffb527ed8bff1bd2f7b90cb5c9b768180e3b30fc0b44724e27479f56f8867551b4b19a9496664418a6b6cbe0960623e SHA512 ca22ea589c19f3c5aae32fb2540646d3b3c8faf86f857dd414caf61b716bc50dea16281955c594a629f684da5ac87eeada6ac68247a9b0545600b739fa436dd7
+DIST gnome-software-3.30.6.tar.xz 5217384 BLAKE2B 6a9478aa7752ea62c391545b5f84191a22c839802bd1ac2118696b9dd954a19003477a688d9f36868a617dbf3dd186fc36a054ce0eac8ba8c7a5eee834732ce4 SHA512 dd98e9e61469fc5566ab569f09bdc06ccb5812a236e305185b911c70364e2983f257e939aed0bb61778163084fb5628d63ff6bd5f056d4a7626a2e771ad6426a
diff --git a/gnome-extra/gnome-software/gnome-software-3.30.6.ebuild b/gnome-extra/gnome-software/gnome-software-3.30.6.ebuild
new file mode 100644
index 00000000000..c7aa1aa96ec
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-3.30.6.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit gnome.org gnome2-utils meson python-any-r1 virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+firmware gnome gtk-doc packagekit spell test udev"
+
+RDEPEND="
+ >=dev-libs/appstream-glib-0.7.14:0
+ >=x11-libs/gdk-pixbuf-2.32.0:2
+ >=dev-libs/glib-2.56:2
+ >=x11-libs/gtk+-3.22.4:3
+ >=dev-libs/json-glib-1.2.0
+ app-crypt/libsecret
+ >=net-libs/libsoup-2.52.0:2.4
+ gnome? ( >=gnome-base/gnome-desktop-3.18.0:3= )
+ spell? ( app-text/gspell:= )
+ sys-auth/polkit
+ packagekit? ( >=app-admin/packagekit-base-1.1.0 )
+ firmware? ( >=sys-apps/fwupd-1.0.3 )
+ udev? ( virtual/libgudev )
+ >=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+ dev-libs/libxml2:2
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? (
+ dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3 )
+ test? (
+ ${PYTHON_DEPS}
+ $(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+# test? ( dev-util/valgrind )
+
+python_check_deps() {
+ use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ xdg_src_prepare
+ sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+ # Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
+ # TODO: Investigate; seems to work outside ebuild .. test/emerge
+ sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_use test tests)
+ $(meson_use spell gspell)
+ $(meson_use gnome gnome_desktop) # Investigate purpose, in relation to shell_extensions too (is it ok to be same USE?)
+ -Dman=true
+ $(meson_use packagekit)
+ # -Dpackagekit_autoremove
+ -Dpolkit=true
+ $(meson_use firmware fwupd)
+ -Dflatpak=false
+ -Drpm_ostree=false
+ -Dsteam=false
+ $(meson_use gnome shell_extensions) # Maybe gnome-shell USE?
+ -Dodrs=false
+ -Dubuntuone=false
+ -Dubuntu_reviews=false
+ -Dwebapps=true
+ $(meson_use udev gudev)
+ -Dsnap=false
+ -Dexternal_appstream=false
+ -Dvalgrind=false
+ $(meson_use gtk-doc gtk_doc)
+ )
+ meson_src_configure
+}
+
+src_test() {
+ virtx meson test -v -C ${BUILD_DIR}
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
diff --git a/gnome-extra/gnome-software/metadata.xml b/gnome-extra/gnome-software/metadata.xml
index 74322fe8c80..92751ac281c 100644
--- a/gnome-extra/gnome-software/metadata.xml
+++ b/gnome-extra/gnome-software/metadata.xml
@@ -7,5 +7,6 @@
</maintainer>
<use>
<flag name="firmware">Enable firmware update support through <pkg>sys-apps/fwupd</pkg></flag>
+ <flag name="packagekit">Enable module for package manager integration</flag>
</use>
</pkgmetadata>