kde-apps/ark: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index 1946a0daada7..84f0f84dbe96 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1 +1,2 @@
 DIST ark-20.08.3.tar.xz 2711708 BLAKE2B c486320f113ab3d12b67aec7589e7973a022415da5dbe01754a9e454c74bb59d2b6556c6934aafd7b5c0ee685e2eca7feee276ad3ebb8a0c6f57aea5bc666a0f SHA512 41ab1498b77f9d152f900eba9e784e8ed28127c849796e42c18db5beb963b0c8f2a1ef1c408d37db02fb21577e5d8e08d8561b72b14042e079a5f1baffa01a01
+DIST ark-20.12.0.tar.xz 2716084 BLAKE2B 1a90dc48c03581168e428e0af6c2ec4ecb6f3e5425b50bf22b790755dafb4fb373eeaafd486fe8ec8f3e37ffaf5e4c5c42fec5db0ff89d8fa0c5215fe87327ad SHA512 1f2e1bb47560e9e5bb81c90b83c5e634cb60f759f81db2e54dfe7caa66bb170c6591538516398fcb90e32c0c86beebee49e37ad8d7f19ed0a343c7d1305a7c33
diff --git a/kde-apps/ark/ark-20.12.0.ebuild b/kde-apps/ark/ark-20.12.0.ebuild
new file mode 100644
index 000000000000..6ef09a3c95ed
--- /dev/null
+++ b/kde-apps/ark/ark-20.12.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KFMIN=5.75.0
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/en/ark https://utils.kde.org/projects/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="zip"
+
+BDEPEND="
+	sys-devel/gettext
+"
+RDEPEND="
+	app-arch/libarchive:=[bzip2,lzma,zlib]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kpty-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.2.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(plugins-clirartest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Optional dependencies:"
+		optfeature "rar archive creation/extraction" app-arch/rar
+		optfeature "rar archive extraction only" app-arch/unar app-arch/unrar
+		optfeature "7-Zip archive support" app-arch/p7zip
+		optfeature "lrz archive support" app-arch/lrzip
+		optfeature "markdown support in text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
+	fi
+	ecm_pkg_postinst
+}