kde-apps: Drop KDE Release Service 20.04.1

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 84 deletions

diff --git a/kde-apps/ark/Manifest b/kde-apps/ark/Manifest
index d6b24a87dc6c..4557542a2ebf 100644
--- a/kde-apps/ark/Manifest
+++ b/kde-apps/ark/Manifest
@@ -1,3 +1,2 @@
 DIST ark-19.12.3.tar.xz 2586112 BLAKE2B c4bde5469dde1ac7cc48b4ecfec260596e2bd3123d9b7c83a5281f45d17675477c2641b708469301e536f04f0e2b469e733c9f95053201682e4af1c2bf378226 SHA512 0f1a155bcfaca1b28b5035943a3d881de89a68c5e8bac156dd1304aa431c5700b6da6dc70e43e82560594bc5aab0ee1d3f3ec50ed4dd15e7f3dd053acbb1a14a
-DIST ark-20.04.1.tar.xz 2587528 BLAKE2B 0efd30d203fb7ab48464a119515fe6588d37804efca866fa91c660c0e946a568b8692dc916a2831bd1f626b17df0b7cad46824fb71fde2bb3094f7226546cfad SHA512 4433b6aee95a88f7a57cca1275a25194cd721b26d38b60059b907c5f7949e75ddc76337f33ed4e07c095622f8e8ee20e9ce1158e02ff620d386fefd6e3472ff1
 DIST ark-20.04.2.tar.xz 2587052 BLAKE2B d05e72bd38070376abf1a69ca46c7d5223c3bcfb25469a5b287a2d124c76249c53cd0b5d3923d9f7205a439767acc5cfd443a0dbf8a75cf834df4ea0e43367c6 SHA512 35f0d17655e9a38c4d9ff4d9777a4198416258cb73d368085d8eaa6eb40622a3e8f8573826789fb978794b84519f131f9e0193b8b279598015dcd89597187cb5
diff --git a/kde-apps/ark/ark-20.04.1.ebuild b/kde-apps/ark/ark-20.04.1.ebuild
deleted file mode 100644
index 31a8d6fb96ac..000000000000
--- a/kde-apps/ark/ark-20.04.1.ebuild
+++ /dev/null
@@ -1,83 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="optional"
-KFMIN=5.70.0
-QTMIN=5.12.3
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="KDE Archiving tool"
-HOMEPAGE="https://kde.org/applications/utilities/org.kde.ark
-https://utils.kde.org/projects/ark/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="bzip2 lzma zip"
-
-BDEPEND="
-	sys-devel/gettext
-"
-RDEPEND="
-	app-arch/libarchive:=[bzip2?,lzma?,zlib]
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	sys-libs/zlib
-	zip? ( >=dev-libs/libzip-1.2.0:= )
-"
-DEPEND="${RDEPEND}
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-"
-
-# bug #560548, last checked with 16.04.1
-RESTRICT+=" test"
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package bzip2 BZip2)
-		$(cmake_use_find_package lzma LibLZMA)
-		$(cmake_use_find_package zip LibZip)
-	)
-
-	ecm_src_configure
-}
-
-pkg_postinst() {
-	ecm_pkg_postinst
-
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		if ! has_version app-arch/rar; then
-			elog "For creating/extracting rar archives, installing app-arch/rar is required."
-			if ! has_version app-arch/unar && ! has_version app-arch/unrar; then
-				elog "Alternatively, for only extracting rar archives, install app-arch/unar (free) or app-arch/unrar (non-free)."
-			fi
-		fi
-
-		has_version app-arch/p7zip || \
-			elog "For handling 7-Zip archives, install app-arch/p7zip."
-
-		has_version app-arch/lrzip || \
-			elog "For handling lrz archives, install app-arch/lrzip."
-	fi
-}