kde-apps/artikulate: 20.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/kde-apps/artikulate/artikulate-20.04.3.ebuild b/kde-apps/artikulate/artikulate-20.04.3.ebuild
new file mode 100644
index 000000000000..dd86f2aa35b9
--- /dev/null
+++ b/kde-apps/artikulate/artikulate-20.04.3.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+KFMIN=5.70.0
+QTMIN=5.14.2
+inherit ecm kde.org
+
+DESCRIPTION="Language learning application that helps improving pronunciation skills"
+HOMEPAGE="https://kde.org/applications/education/org.kde.artikulate"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+gstreamer qtmedia"
+
+REQUIRED_USE="|| ( gstreamer qtmedia )"
+
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=dev-qt/qtxmlpatterns-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	gstreamer? ( >=media-libs/qt-gstreamer-1.2.0[qt5(+)] )
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_GSTREAMER_PLUGIN=$(usex gstreamer)
+		-DBUILD_QTMULTIMEDIA_PLUGIN=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}