kde-apps/cantor: drop 21.04.2*

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 111 deletions

diff --git a/kde-apps/cantor/Manifest b/kde-apps/cantor/Manifest
index 98fe44f2691c..5be6281d74aa 100644
--- a/kde-apps/cantor/Manifest
+++ b/kde-apps/cantor/Manifest
@@ -1,3 +1,2 @@
 DIST cantor-20.12.3.tar.xz 9128948 BLAKE2B 9cc4c6b28ea1f9946ad6d4eeac98b5c47b17b16efc434f355ba2a0f71b23afd4a58ab31df12a881e2a35e836901075d197ad9550409a97f025efdbd21ac919de SHA512 35461a47c9ce4aa4de8ca8496ca33c42691db6be927f30018e174f3234a485c436cca90b6362c8ba325f8bc220a09079069278bdfd08f4510dd7d12ee1a39ed7
-DIST cantor-21.04.2.tar.xz 9145956 BLAKE2B 5701d6ee95a3e68fe479b7c9b473e61830114be984b9ef89f2b52a79f41581e86a9cc4a7eb2537862ba669020cce8f19d51054f6a2dcec30a98b84ed4b64215d SHA512 4847dda3a102daff1211f1c0b65a2c77fe3e65c49f0f6a64630574dbca869dd37526cf5e94aa80cc46cfacd01bbfd0926f9f928218e30e0f8f0325db46dea8be
 DIST cantor-21.04.3.tar.xz 9146060 BLAKE2B da7e55a84df1bf8beb436ecb6b95c0289be1690f7662a6fdd398ff1895c814210f665640b5f617673ab4d557cc9d76016105f99c2431e181db3af14b6905d810 SHA512 9010bb70458296b2a29116e16d8be935d4d1cfe5a6b0554aa24247e3bd76cb97b27a2ffa70608402df588307d5f8c4605ad58ae2ac1d936620cfb2a53d00fadc
diff --git a/kde-apps/cantor/cantor-21.04.2.ebuild b/kde-apps/cantor/cantor-21.04.2.ebuild
deleted file mode 100644
index b63255b7bec2..000000000000
--- a/kde-apps/cantor/cantor-21.04.2.ebuild
+++ /dev/null
@@ -1,110 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{7,8,9} )
-PVCUT=$(ver_cut 1-3)
-KFMIN=5.80.0
-QTMIN=5.15.2
-inherit ecm kde.org lua-single optfeature python-single-r1
-
-DESCRIPTION="Interface for doing mathematics and scientific computing"
-HOMEPAGE="https://apps.kde.org/cantor/ https://edu.kde.org/cantor/"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="+analitza julia lua postscript python qalculate R"
-
-REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} ) python? ( ${PYTHON_REQUIRED_USE} )"
-
-# TODO Add Sage Mathematics Software backend (https://www.sagemath.org)
-DEPEND="
-	app-text/poppler[qt5]
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtprintsupport-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=dev-qt/qtxmlpatterns-${QTMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kpty-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
-	analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
-	julia? ( dev-lang/julia )
-	lua? ( ${LUA_DEPS} )
-	qalculate? (
-		sci-libs/cln
-		sci-libs/libqalculate:=
-	)
-	postscript? ( app-text/libspectre )
-	python? (
-		${PYTHON_DEPS}
-		>=dev-qt/qtdbus-${QTMIN}:5
-	)
-	R? ( dev-lang/R )
-"
-RDEPEND="${DEPEND}
-	!analitza? ( !julia? ( !lua? ( !python? ( !qalculate? ( !R? (
-		|| (
-			sci-mathematics/maxima
-			sci-mathematics/octave
-		)
-	) ) ) ) ) )
-"
-
-RESTRICT+=" test"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	use python && python-single-r1_pkg_setup
-	ecm_pkg_setup
-}
-
-src_configure() {
-	use julia && addpredict /proc/self/mem # bug 602894
-
-	local mycmakeargs=(
-		$(cmake_use_find_package analitza Analitza5)
-		$(cmake_use_find_package julia Julia)
-		$(cmake_use_find_package lua LuaJIT)
-		-DUSE_LIBSPECTRE=$(usex postscript)
-		$(cmake_use_find_package python Python3)
-		$(cmake_use_find_package qalculate Qalculate)
-		$(cmake_use_find_package R R)
-	)
-	use lua && mycmakeargs+=(
-		-DLUAJIT_INCLUDEDIR="${EPREFIX}/$(lua_get_include_dir)"
-		-DLUAJIT_LIBDIR="${EPREFIX}/$(lua_get_cmod_dir)"
-	)
-	use python && mycmakeargs+=( -DPython3_EXECUTABLE="${PYTHON}" )
-	ecm_src_configure
-}
-
-pkg_postinst() {
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		optfeature "Maxima backend" sci-mathematics/maxima
-		optfeature "Octave backend" sci-mathematics/octave
-		optfeature "LaTeX support" virtual/latex-base
-	fi
-	ecm_pkg_postinst
-}