kde-apps/dolphin: 21.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 96 insertions, 0 deletions

diff --git a/kde-apps/dolphin/Manifest b/kde-apps/dolphin/Manifest
index e471c8501c20..686487e876ac 100644
--- a/kde-apps/dolphin/Manifest
+++ b/kde-apps/dolphin/Manifest
@@ -1 +1,2 @@
 DIST dolphin-21.08.3.tar.xz 5327496 BLAKE2B 864016bdb3b30c181eeb158ad0b418c27556f8e0d1bcd2da495cc387667a99e655abcd320a352157156443ab91bd2b1820dce7cb10a4b8d226b5b07dcb46b167 SHA512 918be8ff9ac01ce9e9f0f575a31e70687b24edc08f022cc991922a136bda5900f5cc431b056d2aac8349858e3b9592c365b1cfa8e4bbf01f86eb7be8cbca751e
+DIST dolphin-21.11.90.tar.xz 5320224 BLAKE2B f79416229f2f6afa09e4b4ce377a40cd483219a28e426db202ecb80530c1f61115aad7445ddc52ad0a29ea1e895f7ee4d470c53fa6a0f213117d83ac568cfffa SHA512 a86718bdead1c5ae7f92e6bd4a8b51d4f41bf4b94ae4bbc577447261a1a248207695ee6a9fa5b297d64a8f12ad08a5b287a35872ad720705cbc56d22e09b0257
diff --git a/kde-apps/dolphin/dolphin-21.11.90.ebuild b/kde-apps/dolphin/dolphin-21.11.90.ebuild
new file mode 100644
index 000000000000..f2d7a4d2f119
--- /dev/null
+++ b/kde-apps/dolphin/dolphin-21.11.90.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.88.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Plasma filemanager focusing on usability"
+HOMEPAGE="https://apps.kde.org/dolphin/ https://userbase.kde.org/Dolphin"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="activities semantic-desktop telemetry"
+
+DEPEND="
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5=
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	semantic-desktop? (
+		>=kde-apps/baloo-widgets-${PVCUT}:5
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	)
+	telemetry? ( dev-libs/kuserfeedback:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kio-extras-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package semantic-desktop KF5BalooWidgets)
+		$(cmake_use_find_package semantic-desktop KF5FileMetaData)
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# servicemenuinstaller requires ruby, no thanks
+		# dolphinmainwindowtest, kitemlistcontrollertest, kfileitemlistviewtest, kfileitemmodeltest hang forever
+		# placesitemmodeltest requires DBus
+		-E "(servicemenuinstaller|dolphinmainwindowtest|kfileitemlistviewtest|kfileitemmodeltest|kitemlistcontrollertest|placesitemmodeltest)"
+	)
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "compress/extract and other actions" kde-apps/ark:${SLOT}
+		optfeature "crypto actions" kde-apps/kleopatra:${SLOT}
+		optfeature "video file thumbnails" kde-apps/ffmpegthumbs:${SLOT}
+		optfeature "graphics file thumbnails" kde-apps/thumbnailers:${SLOT}
+		optfeature "'Share' context menu actions" kde-frameworks/purpose:${SLOT}
+	fi
+	ecm_pkg_postinst
+}