kde-apps: Drop KDE Release Service 19.12.2

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 108 deletions

diff --git a/kde-apps/kate/Manifest b/kde-apps/kate/Manifest
index 42e6b733d581..ce7966c12562 100644
--- a/kde-apps/kate/Manifest
+++ b/kde-apps/kate/Manifest
@@ -1,3 +1,2 @@
 DIST kate-19.08.3.tar.xz 5844532 BLAKE2B 34aaceab92783a869de616be9290887f75eba5ef6198e93d90a71d62b441a907a7893916c72ac85c46d6156330322d5297c60c8c9b43cbcd615c05b51cdd0000 SHA512 0a0b33858bd4856bdf29d354603d33541b2c0aab134025db3014aa31cf3231fa2bcc244252872c0b51c28b7cd715556966d9049ce85a8ad614e1f552479c1bc8
-DIST kate-19.12.2.tar.xz 5733072 BLAKE2B 496cf247ff38fe8fb7951f4c348ed3302a161812e50a6c4df2caa9d105d601f2ccda4bccb1c7aa15b9b27c45201b0c43d5d925e0af236edea9a385b06501d96e SHA512 3c85c2e05593b67591366740d34f7c247ac6ff5f411681c100c6be64d8f5f77d4d0e3a2439c9cb1210084880578b107611d03355d3fe2400226c5755c58f1c61
 DIST kate-19.12.3.tar.xz 5795816 BLAKE2B 567b0c37f0b50533eeb19a527f7527ae050b62c8a50d46bbfac06226f109cd024b7626abc7defa32b9a654e231f6f04246a3410ace92f40fc25fb22a6f893c82 SHA512 aa6a2c44a8c5892e61ac80df676da6059e61dd93f5e2934e0547040d89379f9f3ae90f46b8e043edf463228ef5b0ab3f795b8ab3dd6c488d0ba0c55cf20bd817
diff --git a/kde-apps/kate/kate-19.12.2.ebuild b/kde-apps/kate/kate-19.12.2.ebuild
deleted file mode 100644
index 7d82c73d1785..000000000000
--- a/kde-apps/kate/kate-19.12.2.ebuild
+++ /dev/null
@@ -1,107 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KFMIN=5.63.0
-QTMIN=5.12.3
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
-HOMEPAGE="https://kate-editor.org/
-https://kde.org/applications/utilities/org.kde.kate"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="activities +filebrowser lspclient +projects plasma +snippets sql"
-
-DEPEND="
-	>=kde-frameworks/kcodecs-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
-	filebrowser? ( >=kde-frameworks/kbookmarks-${KFMIN}:5 )
-	lspclient? ( >=kde-frameworks/kitemmodels-${KFMIN}:5 )
-	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
-	projects? (
-		>=kde-frameworks/knewstuff-${KFMIN}:5
-		>=kde-frameworks/threadweaver-${KFMIN}:5
-	)
-	snippets? ( >=kde-frameworks/knewstuff-${KFMIN}:5 )
-	sql? (
-		>=kde-frameworks/kwallet-${KFMIN}:5
-		>=dev-qt/qtsql-${QTMIN}:5
-	)
-"
-RDEPEND="${DEPEND}
-	!kde-misc/ktexteditorpreviewplugin
-"
-
-src_prepare() {
-	ecm_src_prepare
-
-	# delete colliding kwrite translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and -name "kwrite*" -delete || die
-		rm -rf po/*/docs/kwrite || die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package activities KF5Activities)
-		-DBUILD_filebrowser=$(usex filebrowser)
-		-DBUILD_lspclient=$(usex lspclient)
-		-DBUILD_sessionapplet=$(usex plasma)
-		-DBUILD_project=$(usex projects)
-		-DBUILD_snippets=$(usex snippets)
-		-DBUILD_katesql=$(usex sql)
-		-DBUILD_kwrite=FALSE
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	# tests hang
-	local myctestargs=(
-		-E "(session_manager_test|sessions_action_test)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	ecm_pkg_postinst
-
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		elog "The functionality of ktexteditorpreview plugin can be extended with:"
-		elog "  kde-misc/kmarkdownwebview"
-		elog "  media-gfx/kgraphviewer"
-	fi
-}