kde-apps/kget: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/kde-apps/kget/Manifest b/kde-apps/kget/Manifest
index 6f2dde0fe8f0..07b798871093 100644
--- a/kde-apps/kget/Manifest
+++ b/kde-apps/kget/Manifest
@@ -1 +1,2 @@
 DIST kget-20.08.3.tar.xz 5583180 BLAKE2B d0893aedbbf744bde38a502f87b2340c295dc107aaafdf0a91febc6281d96694948c22b1ca0e404838b68f7677b06097b22cef45e8c076d4e20e0efbd8d6ce92 SHA512 91def334f76e37a53e89e6e696fb955714c1e5239bd85f07b44e5bc625122aa3549a76a0776418e58f3bc76f6052900d9ef0fc595da73d5e98779e3565346540
+DIST kget-20.12.0.tar.xz 5583908 BLAKE2B 0f72e4a8796245621bd67701d3fb13ad3404c540fd5541ac7201474843175c5798e8001d840a1c9e8ac4353826f157a4e9944bc568afae9a198374225c865810 SHA512 17e550f96a7f5a486dddae131ed25f25142fbb4f83fbed678f5488e4762face1c5a2fa8c3451700449d35a0daed9ff7a85d85ef164a3dd7f8d981059815324dc
diff --git a/kde-apps/kget/kget-20.12.0.ebuild b/kde-apps/kget/kget-20.12.0.ebuild
new file mode 100644
index 000000000000..0a1fd2d9bf25
--- /dev/null
+++ b/kde-apps/kget/kget-20.12.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.75.0
+QTMIN=5.15.1
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Advanced download manager by KDE"
+HOMEPAGE="https://apps.kde.org/en/kget"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="bittorrent gpg kde mms sqlite"
+
+RDEPEND="
+	>=app-crypt/qca-2.3.0:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdelibs4support-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	bittorrent? ( net-libs/libktorrent:5 )
+	gpg? ( app-crypt/gpgme[qt5] )
+	kde? ( kde-plasma/libkworkspace:5 )
+	mms? ( media-libs/libmms )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package bittorrent KF5Torrent)
+		$(cmake_use_find_package gpg Gpgmepp)
+		$(cmake_use_find_package kde LibKWorkspace)
+		$(cmake_use_find_package mms LibMms)
+		$(cmake_use_find_package sqlite Sqlite)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 756817: schedulertest fails, see also upstream commit 45735cfa
+	# filedeletertest hangs.
+	local myctestargs=(
+		-E "(schedulertest|filedeletertest)"
+	)
+
+	ecm_src_test
+}