kde-apps/kwave: 21.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index acb22700c867..feb0a6eafaf3 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-20.12.3.tar.xz 6911104 BLAKE2B 17cc2c5a1b14b8c46548fc3d8c65a37c5f42f49a6656f54cef4549d5b8fbda08f3e491a11a5c46e328c3abc6fbcb4e09dc45529fe14e7a78ab031b1d0937cbdf SHA512 9854836fc328dfded8494c03137d940c8ecfc0409e0f8ea85b34d51fb1f7d077c3f3e9e8e439acdf9da66037de0da65dabe8db7422b5bccbadcbaff599e9893a
 DIST kwave-21.04.2.tar.xz 6898836 BLAKE2B 7917baecb9653350df71cf70eb68c26951b8ae5afa4661ae7879f3436f5301aab3fb8b1c2f203157b1c5c0bfac315d629d31d894dd8b9d93228a4e1be94e33df SHA512 4508f4dc30b8fd0e115e4d36d9b0cc00552893666c850020827c6ff36aab41e31d0064a2dd57656b4193f8a3eb71b9c95a8eeff59e7c1424ff43c8fde8b09942
+DIST kwave-21.04.3.tar.xz 6899140 BLAKE2B 963b2da276e9c897f6b431a665f880a6346dd9298e6f818b291a6a51c17b015ef3c3e1928caa4ec57d9780c982e58107966d39b618d40c2c75a3263c2e74bc9c SHA512 08a648e75ca3a331025ad84f02be7c04b6ec9e68ba251436fa923add35bb3132765519b9bc9fda44b01a45d8b3a9b85f12ac3eb267a8313593d360eb08161f6b
diff --git a/kde-apps/kwave/kwave-21.04.3.ebuild b/kde-apps/kwave/kwave-21.04.3.ebuild
new file mode 100644
index 000000000000..d8dc219b5841
--- /dev/null
+++ b/kde-apps/kwave/kwave-21.04.3.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}