kde-apps/spectacle: 20.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/kde-apps/spectacle/Manifest b/kde-apps/spectacle/Manifest
index d2ce1fe66a65..2dc59806bf50 100644
--- a/kde-apps/spectacle/Manifest
+++ b/kde-apps/spectacle/Manifest
@@ -1,2 +1,3 @@
 DIST spectacle-20.08.3.tar.xz 1156220 BLAKE2B 3ebf54668fda63db6c1d938beedd287d7570749a6f9c6de89752d42abb7fe75687a6e3135a0fcd8f86b741a286518040627b2da0fc96ba029dfd1e1ede9a04ef SHA512 baae34ae4c7b3811e008ae8c1c2d6d6603fd39533279cc3ed79d4a38fa6cb3879ece30bc9ed1b1a5163691dcb2adea7e8cd3d655788f680feb94c38ad53610ac
 DIST spectacle-20.12.1.tar.xz 1163912 BLAKE2B 5ba6ff90e9f98a711eaf99b04f4bc6799a1bedf7c91c836657b51fb204cb7607ea219fc9c6b2c343b4c21ac980d42be3094e409833e81c0e1db4fa5f15cd169a SHA512 7df1907ed350d19d48e522c7a591e3d4464a60d18b9f88242713062ea9a68aa966221fd2e6c3548cf0cc325fa7a7e9ec0c3d9856edf95c2cdcf74b950f10ba60
+DIST spectacle-20.12.2.tar.xz 1164120 BLAKE2B 431176e2c42cd7cbacb3c12ea92293eca759c3c5b024214c1eb5aca5eed3123cb4c3afe44ab29b438d1677cb35fa67ca94ee7128f126859b9fcd78883d559241 SHA512 c0dfffe4a9ebd3e2e3185f4f6bde03363b63d90e771bbe0610ccb42a79178a21d413db50a1842ad7e236f2ebc736cb3915d3614194b38432289471bff39c93f9
diff --git a/kde-apps/spectacle/spectacle-20.12.2.ebuild b/kde-apps/spectacle/spectacle-20.12.2.ebuild
new file mode 100644
index 000000000000..6c5c1429821e
--- /dev/null
+++ b/kde-apps/spectacle/spectacle-20.12.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.75.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Screenshot capture utility"
+HOMEPAGE="https://apps.kde.org/en/spectacle"
+
+LICENSE="LGPL-2+ handbook? ( FDL-1.3 ) kipi? ( GPL-2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+annotate kipi share"
+
+# TODO: Qt5Svg leaking from media-libs/kimageannotator
+DEPEND="
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	x11-libs/libxcb
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	annotate? ( media-libs/kimageannotator )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# Unnecessary with >=media-libs/kimageannotator-0.4.0
+	sed -e "/find_package\s*(\s*X11/d" -e "/find_package\s*(\s*kColorPicker/d" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package annotate kImageAnnotator)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}