kde-apps/spectacle: 21.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/kde-apps/spectacle/Manifest b/kde-apps/spectacle/Manifest
index 37a4a7d87ae2..704db0eb03ce 100644
--- a/kde-apps/spectacle/Manifest
+++ b/kde-apps/spectacle/Manifest
@@ -1 +1,2 @@
 DIST spectacle-20.12.3.tar.xz 1170540 BLAKE2B 865c4f7a2b8a3edf727f551c64ce35847a880023773b72531ea324addf5f0ac327261a87e35cdea6ec1f7eb4b75d2f8b86c3d1b7fc7719959623653ebe542a93 SHA512 4749916ff1557d89c3a8aeae06ce2da4e3f5bbbc3495a588209d797453b265447a857266889a81178f33b12631f6ec29be7a65a3f98f27de604c198e997795dc
+DIST spectacle-21.04.0.tar.xz 1168056 BLAKE2B 02df7c3bcb3926028a78c1efdc22690ffff429e4b3fd6087127bbe7ce96211b192d88460a1336fe84591fda0f4995cc808e451fee1b36b207e3c4dafd2acbbd1 SHA512 40ccfe9f3f0373cfdb3a16fc215536520da4ce2a9bff8cf5e4924a24e6b5058a209a55261d77bb5d9d645245d139ffdb9f89dc2dd5d569f80be55fe4540caa62
diff --git a/kde-apps/spectacle/spectacle-21.04.0.ebuild b/kde-apps/spectacle/spectacle-21.04.0.ebuild
new file mode 100644
index 000000000000..bc35417ba4b1
--- /dev/null
+++ b/kde-apps/spectacle/spectacle-21.04.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.80.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Screenshot capture utility"
+HOMEPAGE="https://apps.kde.org/en/spectacle"
+
+LICENSE="LGPL-2+ handbook? ( FDL-1.3 ) kipi? ( GPL-2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+annotate kipi share"
+
+# TODO: Qt5Svg leaking from media-libs/kimageannotator
+DEPEND="
+	>=dev-qt/qdbus-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	x11-libs/libxcb
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-image
+	annotate? ( >=media-libs/kimageannotator-0.4.1 )
+	kipi? ( >=kde-apps/libkipi-${PVCUT}:5= )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+"
+RDEPEND="${DEPEND}
+	kipi? ( >=kde-apps/kipi-plugins-${PVCUT}:5 )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# Unnecessary with >=media-libs/kimageannotator-0.4.0
+	sed -e "/find_package\s*(\s*X11/d" -e "/find_package\s*(\s*kColorPicker/d" \
+		-i CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package annotate kImageAnnotator)
+		$(cmake_use_find_package kipi KF5Kipi)
+		$(cmake_use_find_package share KF5Purpose)
+	)
+	ecm_src_configure
+}