kde-plasma/drkonqi: Fix random 113 errors (user_not_insider)

KDE-Bug: https://bugs.kde.org/show_bug.cgi?id=421187
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 121 insertions, 0 deletions

diff --git a/kde-plasma/drkonqi/drkonqi-5.18.5-r1.ebuild b/kde-plasma/drkonqi/drkonqi-5.18.5-r1.ebuild
new file mode 100644
index 000000000000..0bef1482efdd
--- /dev/null
+++ b/kde-plasma/drkonqi/drkonqi-5.18.5-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KFMIN=5.66.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwayland-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlrpcclient-${KFMIN}:5
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-init-bools-w-false.patch" # in Plasma/5.18, KDE-bug 421187
+)
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X Qt5X11Extras)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# needs network access, bug #698510
+	local myctestargs=(
+		-E "(connectiontest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	if ! has_version "sys-devel/gdb"; then
+		elog "For more usability consider installing the following package:"
+		elog "    sys-devel/gdb - Easier debugging support"
+	fi
+}
diff --git a/kde-plasma/drkonqi/files/drkonqi-5.18.5-init-bools-w-false.patch b/kde-plasma/drkonqi/files/drkonqi-5.18.5-init-bools-w-false.patch
new file mode 100644
index 000000000000..6ce33a7198ab
--- /dev/null
+++ b/kde-plasma/drkonqi/files/drkonqi-5.18.5-init-bools-w-false.patch
@@ -0,0 +1,50 @@
+From c517b795936fdab641849ca83ec8c3e253e32de8 Mon Sep 17 00:00:00 2001
+From: Harald Sitter <sitter@kde.org>
+Date: Tue, 12 May 2020 12:25:52 +0200
+Subject: initialize bools to false by default
+
+Summary:
+This should fix random 113 errors (user_not_insider) coming out of the api
+
+I can't really reproduce the problem other than by setting the bools
+explicitly to true. Seeing as they were previously not set explicitly
+they could very well end up true accidentally.
+To fix this let's set them explicitly false.
+
+BUG: 421187
+FIXED-IN: 5.18.6
+
+Test Plan:
+hoping for the best!
+tests still pass tho
+
+Reviewers: davidedmundson, apol
+
+Reviewed By: apol
+
+Subscribers: plasma-devel
+
+Tags: #plasma
+
+Differential Revision: https://phabricator.kde.org/D29675
+---
+ src/bugzillaintegration/libbugzilla/clients/commands/newattachment.h | 4 ++--
+ 1 file changed, 2 insertions(+), 2 deletions(-)
+
+diff --git a/src/bugzillaintegration/libbugzilla/clients/commands/newattachment.h b/src/bugzillaintegration/libbugzilla/clients/commands/newattachment.h
+index d30f379..8b4e4bb 100644
+--- a/src/bugzillaintegration/libbugzilla/clients/commands/newattachment.h
++++ b/src/bugzillaintegration/libbugzilla/clients/commands/newattachment.h
+@@ -34,8 +34,8 @@ class NewAttachment : public JsonCommand
+     BUGZILLA_MEMBER_PROPERTY(QString, summary);
+     BUGZILLA_MEMBER_PROPERTY(QString, content_type);
+     BUGZILLA_MEMBER_PROPERTY(QString, comment);
+-    BUGZILLA_MEMBER_PROPERTY(bool, is_patch);
+-    BUGZILLA_MEMBER_PROPERTY(bool, is_private);
++    BUGZILLA_MEMBER_PROPERTY(bool, is_patch) = false;
++    BUGZILLA_MEMBER_PROPERTY(bool, is_private) = false;
+ 
+     // flags property is not supported at this time
+ 
+-- 
+cgit v1.1